tests/checkpatch.pl

   1 #!/usr/bin/perl -w
   2
   3 # This script has been copied from Linux Kernel sources.
   4 #
   5 # (c) 2001, Dave Jones. (the file handling bit)
   6 # (c) 2005, Joel Schopp <jschopp@austin.ibm.com> (the ugly bit)
   7 # (c) 2007,2008, Andy Whitcroft <apw@uk.ibm.com> (new conditions, test suite)
   8 # (c) 2008-2010 Andy Whitcroft <apw@canonical.com>
   9 # Licensed under the terms of the GNU GPL License version 2
  10
  11 use strict;
  12
  13 my $P = $0;
  14 $P =~ s@.*/@@g;
  15
  16 my $V = '0.32';
  17
  18 use Getopt::Long qw(:config no_auto_abbrev);
  19
  20 my $quiet = 0;
  21 my $tree = 1;
  22 my $chk_signoff = 1;
  23 my $chk_patch = 1;
  24 my $tst_only;
  25 my $emacs = 0;
  26 my $terse = 0;
  27 my $file = 0;
  28 my $check = 0;
  29 my $summary = 1;
  30 my $mailback = 0;
  31 my $summary_file = 0;
  32 my $show_types = 0;
  33 my $root;
  34 my %debug;
  35 my %ignore_type = ();
  36 my @ignore = ();
  37 my $help = 0;
  38 my $configuration_file = ".checkpatch.conf";
  39
  40 sub help {
  41         my ($exitcode) = @_;
  42
  43         print << "EOM";
  44 Usage: $P [OPTION]... [FILE]...
  45 Version: $V
  46
  47 Options:
  48   -q, --quiet                quiet
  49   --no-tree                  run without a kernel tree
  50   --no-signoff               do not check for 'Signed-off-by' line
  51   --patch                    treat FILE as patchfile (default)
  52   --emacs                    emacs compile window format
  53   --terse                    one line per report
  54   -f, --file                 treat FILE as regular source file
  55   --subjective, --strict     enable more subjective tests
  56   --ignore TYPE(,TYPE2...)   ignore various comma separated message types
  57   --show-types               show the message "types" in the output
  58   --root=PATH                PATH to the kernel tree root
  59   --no-summary               suppress the per-file summary
  60   --mailback                 only produce a report in case of warnings/errors
  61   --summary-file             include the filename in summary
  62   --debug KEY=[0|1]          turn on/off debugging of KEY, where KEY is one of
  63                              'values', 'possible', 'type', and 'attr' (default
  64                              is all off)
  65   --test-only=WORD           report only warnings/errors containing WORD
  66                              literally
  67   -h, --help, --version      display this help and exit
  68
  69 When FILE is - read standard input.
  70 EOM
  71
  72         exit($exitcode);
  73 }
  74
  75 my $conf = which_conf($configuration_file);
  76 if (-f $conf) {
  77         my @conf_args;
  78         open(my $conffile, '<', "$conf")
  79             or warn "$P: Can't find a readable $configuration_file file $!\n";
  80
  81         while (<$conffile>) {
  82                 my $line = $_;
  83
  84                 $line =~ s/\s*\n?$//g;
  85                 $line =~ s/^\s*//g;
  86                 $line =~ s/\s+/ /g;
  87
  88                 next if ($line =~ m/^\s*#/);
  89                 next if ($line =~ m/^\s*$/);
  90
  91                 my @words = split(" ", $line);
  92                 foreach my $word (@words) {
  93                         last if ($word =~ m/^#/);
  94                         push (@conf_args, $word);
  95                 }
  96         }
  97         close($conffile);
  98         unshift(@ARGV, @conf_args) if @conf_args;
  99 }
 100
 101 GetOptions(
 102         'q|quiet+'      => \$quiet,
 103         'tree!'         => \$tree,
 104         'signoff!'      => \$chk_signoff,
 105         'patch!'        => \$chk_patch,
 106         'emacs!'        => \$emacs,
 107         'terse!'        => \$terse,
 108         'f|file!'       => \$file,
 109         'subjective!'   => \$check,
 110         'strict!'       => \$check,
 111         'ignore=s'      => \@ignore,
 112         'show-types!'   => \$show_types,
 113         'root=s'        => \$root,
 114         'summary!'      => \$summary,
 115         'mailback!'     => \$mailback,
 116         'summary-file!' => \$summary_file,
 117
 118         'debug=s'       => \%debug,
 119         'test-only=s'   => \$tst_only,
 120         'h|help'        => \$help,
 121         'version'       => \$help
 122 ) or help(1);
 123
 124 help(0) if ($help);
 125
 126 my $exit = 0;
 127
 128 if ($#ARGV < 0) {
 129         print "$P: no input files\n";
 130         exit(1);
 131 }
 132
 133 @ignore = split(/,/, join(',',@ignore));
 134 foreach my $word (@ignore) {
 135         $word =~ s/\s*\n?$//g;
 136         $word =~ s/^\s*//g;
 137         $word =~ s/\s+/ /g;
 138         $word =~ tr/[a-z]/[A-Z]/;
 139
 140         next if ($word =~ m/^\s*#/);
 141         next if ($word =~ m/^\s*$/);
 142
 143         $ignore_type{$word}++;
 144 }
 145
 146 my $dbg_values = 0;
 147 my $dbg_possible = 0;
 148 my $dbg_type = 0;
 149 my $dbg_attr = 0;
 150 for my $key (keys %debug) {
 151         ## no critic
 152         eval "\${dbg_$key} = '$debug{$key}';";
 153         die "$@" if ($@);
 154 }
 155
 156 my $rpt_cleaners = 0;
 157
 158 if ($terse) {
 159         $emacs = 1;
 160         $quiet++;
 161 }
 162
 163 if ($tree) {
 164         if (defined $root) {
 165                 if (!top_of_kernel_tree($root)) {
 166                         die "$P: $root: --root does not point at a valid tree\n";
 167                 }
 168         } else {
 169                 if (top_of_kernel_tree('.')) {
 170                         $root = '.';
 171                 } elsif ($0 =~ m@(.*)/scripts/[^/]*$@ &&
 172                                                 top_of_kernel_tree($1)) {
 173                         $root = $1;
 174                 }
 175         }
 176
 177         if (!defined $root) {
 178                 print "Must be run from the top-level dir. of a kernel tree\n";
 179                 exit(2);
 180         }
 181 }
 182
 183 my $emitted_corrupt = 0;
 184
 185 our $Ident      = qr{
 186                         [A-Za-z_][A-Za-z\d_]*
 187                         (?:\s*\#\#\s*[A-Za-z_][A-Za-z\d_]*)*
 188                 }x;
 189 our $Storage    = qr{extern|static|asmlinkage};
 190 our $Sparse     = qr{
 191                         __user|
 192                         __kernel|
 193                         __force|
 194                         __iomem|
 195                         __must_check|
 196                         __init_refok|
 197                         __kprobes|
 198                         __ref|
 199                         __rcu
 200                 }x;
 201
 202 # Notes to $Attribute:
 203 # We need \b after 'init' otherwise 'initconst' will cause a false positive in a check
 204 our $Attribute  = qr{
 205                         const|
 206                         __percpu|
 207                         __nocast|
 208                         __safe|
 209                         __bitwise__|
 210                         __packed__|
 211                         __packed2__|
 212                         __naked|
 213                         __maybe_unused|
 214                         __always_unused|
 215                         __noreturn|
 216                         __used|
 217                         __cold|
 218                         __noclone|
 219                         __deprecated|
 220                         __read_mostly|
 221                         __kprobes|
 222                         __(?:mem|cpu|dev|)(?:initdata|initconst|init\b)|
 223                         ____cacheline_aligned|
 224                         ____cacheline_aligned_in_smp|
 225                         ____cacheline_internodealigned_in_smp|
 226                         __weak
 227                   }x;
 228 our $Modifier;
 229 our $Inline     = qr{inline|__always_inline|noinline};
 230 our $Member     = qr{->$Ident|\.$Ident|\[[^]]*\]};
 231 our $Lval       = qr{$Ident(?:$Member)*};
 232
 233 our $Constant   = qr{(?:[0-9]+|0x[0-9a-fA-F]+)[UL]*};
 234 our $Assignment = qr{(?:\*\=|/=|%=|\+=|-=|<<=|>>=|&=|\^=|\|=|=)};
 235 our $Compare    = qr{<=|>=|==|!=|<|>};
 236 our $Operators  = qr{
 237                         <=|>=|==|!=|
 238                         =>|->|<<|>>|<|>|!|~|
 239                         &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%
 240                   }x;
 241
 242 our $NonptrType;
 243 our $Type;
 244 our $Declare;
 245
 246 our $NON_ASCII_UTF8     = qr{
 247         [\xC2-\xDF][\x80-\xBF]               # non-overlong 2-byte
 248         |  \xE0[\xA0-\xBF][\x80-\xBF]        # excluding overlongs
 249         | [\xE1-\xEC\xEE\xEF][\x80-\xBF]{2}  # straight 3-byte
 250         |  \xED[\x80-\x9F][\x80-\xBF]        # excluding surrogates
 251         |  \xF0[\x90-\xBF][\x80-\xBF]{2}     # planes 1-3
 252         | [\xF1-\xF3][\x80-\xBF]{3}          # planes 4-15
 253         |  \xF4[\x80-\x8F][\x80-\xBF]{2}     # plane 16
 254 }x;
 255
 256 our $UTF8       = qr{
 257         [\x09\x0A\x0D\x20-\x7E]              # ASCII
 258         | $NON_ASCII_UTF8
 259 }x;
 260
 261 our $typeTypedefs = qr{(?x:
 262         (?:__)?(?:u|s|be|le)(?:8|16|32|64)|
 263         atomic_t
 264 )};
 265
 266 our $logFunctions = qr{(?x:
 267         printk(?:_ratelimited|_once|)|
 268         [a-z0-9]+_(?:printk|emerg|alert|crit|err|warning|warn|notice|info|debug|dbg|vdbg|devel|cont|WARN)(?:_ratelimited|_once|)|
 269         WARN(?:_RATELIMIT|_ONCE|)|
 270         panic|
 271         MODULE_[A-Z_]+
 272 )};
 273
 274 our $signature_tags = qr{(?xi:
 275         Signed-off-by:|
 276         Acked-by:|
 277         Tested-by:|
 278         Reviewed-by:|
 279         Reported-by:|
 280         To:|
 281         Cc:
 282 )};
 283
 284 our @typeList = (
 285         qr{void},
 286         qr{(?:unsigned\s+)?char},
 287         qr{(?:unsigned\s+)?short},
 288         qr{(?:unsigned\s+)?int},
 289         qr{(?:unsigned\s+)?long},
 290         qr{(?:unsigned\s+)?long\s+int},
 291         qr{(?:unsigned\s+)?long\s+long},
 292         qr{(?:unsigned\s+)?long\s+long\s+int},
 293         qr{unsigned},
 294         qr{float},
 295         qr{double},
 296         qr{bool},
 297         qr{struct\s+$Ident},
 298         qr{union\s+$Ident},
 299         qr{enum\s+$Ident},
 300         qr{${Ident}_t},
 301         qr{${Ident}_handler},
 302         qr{${Ident}_handler_fn},
 303 );
 304 our @modifierList = (
 305         qr{fastcall},
 306 );
 307
 308 our $allowed_asm_includes = qr{(?x:
 309         irq|
 310         memory
 311 )};
 312 # memory.h: ARM has a custom one
 313
 314 sub build_types {
 315         my $mods = "(?x:  \n" . join("|\n  ", @modifierList) . "\n)";
 316         my $all = "(?x:  \n" . join("|\n  ", @typeList) . "\n)";
 317         $Modifier       = qr{(?:$Attribute|$Sparse|$mods)};
 318         $NonptrType     = qr{
 319                         (?:$Modifier\s+|const\s+)*
 320                         (?:
 321                                 (?:typeof|__typeof__)\s*\(\s*\**\s*$Ident\s*\)|
 322                                 (?:$typeTypedefs\b)|
 323                                 (?:${all}\b)
 324                         )
 325                         (?:\s+$Modifier|\s+const)*
 326                   }x;
 327         $Type   = qr{
 328                         $NonptrType
 329                         (?:[\s\*]+\s*const|[\s\*]+|(?:\s*\[\s*\])+)?
 330                         (?:\s+$Inline|\s+$Modifier)*
 331                   }x;
 332         $Declare        = qr{(?:$Storage\s+)?$Type};
 333 }
 334 build_types();
 335
 336 our $match_balanced_parentheses = qr/(\((?:[^\(\)]+|(-1))*\))/;
 337
 338 our $Typecast   = qr{\s*(\(\s*$NonptrType\s*\)){0,1}\s*};
 339 our $LvalOrFunc = qr{($Lval)\s*($match_balanced_parentheses{0,1})\s*};
 340
 341 sub deparenthesize {
 342         my ($string) = @_;
 343         return "" if (!defined($string));
 344         $string =~ s@^\s*\(\s*@@g;
 345         $string =~ s@\s*\)\s*$@@g;
 346         $string =~ s@\s+@ @g;
 347         return $string;
 348 }
 349
 350 $chk_signoff = 0 if ($file);
 351
 352 my @dep_includes = ();
 353 my @dep_functions = ();
 354 my $removal = "Documentation/feature-removal-schedule.txt";
 355 if ($tree && -f "$root/$removal") {
 356         open(my $REMOVE, '<', "$root/$removal") ||
 357                                 die "$P: $removal: open failed - $!\n";
 358         while (<$REMOVE>) {
 359                 if (/^Check:\s+(.*\S)/) {
 360                         for my $entry (split(/[, ]+/, $1)) {
 361                                 if ($entry =~ m@include/(.*)@) {
 362                                         push(@dep_includes, $1);
 363
 364                                 } elsif ($entry !~ m@/@) {
 365                                         push(@dep_functions, $entry);
 366                                 }
 367                         }
 368                 }
 369         }
 370         close($REMOVE);
 371 }
 372
 373 my @rawlines = ();
 374 my @lines = ();
 375 my $vname;
 376 for my $filename (@ARGV) {
 377         my $FILE;
 378         if ($file) {
 379                 open($FILE, '-|', "diff -u /dev/null $filename") ||
 380                         die "$P: $filename: diff failed - $!\n";
 381         } elsif ($filename eq '-') {
 382                 open($FILE, '<&STDIN');
 383         } else {
 384                 open($FILE, '<', "$filename") ||
 385                         die "$P: $filename: open failed - $!\n";
 386         }
 387         if ($filename eq '-') {
 388                 $vname = 'Your patch';
 389         } else {
 390                 $vname = $filename;
 391         }
 392         while (<$FILE>) {
 393                 chomp;
 394                 push(@rawlines, $_);
 395         }
 396         close($FILE);
 397         if (!process($filename)) {
 398                 $exit = 1;
 399         }
 400         @rawlines = ();
 401         @lines = ();
 402 }
 403
 404 exit($exit);
 405
 406 sub top_of_kernel_tree {
 407         my ($root) = @_;
 408
 409         my @tree_check = (
 410                 "COPYING", "CREDITS", "Kbuild", "MAINTAINERS", "Makefile",
 411                 "README", "Documentation", "arch", "include", "drivers",
 412                 "fs", "init", "ipc", "kernel", "lib", "scripts",
 413         );
 414
 415         foreach my $check (@tree_check) {
 416                 if (! -e $root . '/' . $check) {
 417                         return 0;
 418                 }
 419         }
 420         return 1;
 421     }
 422
 423 sub parse_email {
 424         my ($formatted_email) = @_;
 425
 426         my $name = "";
 427         my $address = "";
 428         my $comment = "";
 429
 430         if ($formatted_email =~ /^(.*)<(\S+\@\S+)>(.*)$/) {
 431                 $name = $1;
 432                 $address = $2;
 433                 $comment = $3 if defined $3;
 434         } elsif ($formatted_email =~ /^\s*<(\S+\@\S+)>(.*)$/) {
 435                 $address = $1;
 436                 $comment = $2 if defined $2;
 437         } elsif ($formatted_email =~ /(\S+\@\S+)(.*)$/) {
 438                 $address = $1;
 439                 $comment = $2 if defined $2;
 440                 $formatted_email =~ s/$address.*$//;
 441                 $name = $formatted_email;
 442                 $name =~ s/^\s+|\s+$//g;
 443                 $name =~ s/^\"|\"$//g;
 444                 # If there's a name left after stripping spaces and
 445                 # leading quotes, and the address doesn't have both
 446                 # leading and trailing angle brackets, the address
 447                 # is invalid. ie:
 448                 #   "joe smith joe@smith.com" bad
 449                 #   "joe smith <joe@smith.com" bad
 450                 if ($name ne "" && $address !~ /^<[^>]+>$/) {
 451                         $name = "";
 452                         $address = "";
 453                         $comment = "";
 454                 }
 455         }
 456
 457         $name =~ s/^\s+|\s+$//g;
 458         $name =~ s/^\"|\"$//g;
 459         $address =~ s/^\s+|\s+$//g;
 460         $address =~ s/^\<|\>$//g;
 461
 462         if ($name =~ /[^\w \-]/i) { ##has "must quote" chars
 463                 $name =~ s/(?<!\\)"/\\"/g; ##escape quotes
 464                 $name = "\"$name\"";
 465         }
 466
 467         return ($name, $address, $comment);
 468 }
 469
 470 sub format_email {
 471         my ($name, $address) = @_;
 472
 473         my $formatted_email;
 474
 475         $name =~ s/^\s+|\s+$//g;
 476         $name =~ s/^\"|\"$//g;
 477         $address =~ s/^\s+|\s+$//g;
 478
 479         if ($name =~ /[^\w \-]/i) { ##has "must quote" chars
 480                 $name =~ s/(?<!\\)"/\\"/g; ##escape quotes
 481                 $name = "\"$name\"";
 482         }
 483
 484         if ("$name" eq "") {
 485                 $formatted_email = "$address";
 486         } else {
 487                 $formatted_email = "$name <$address>";
 488         }
 489
 490         return $formatted_email;
 491 }
 492
 493 sub which_conf {
 494         my ($conf) = @_;
 495
 496         foreach my $path (split(/:/, ".:$ENV{HOME}:.scripts")) {
 497                 if (-e "$path/$conf") {
 498                         return "$path/$conf";
 499                 }
 500         }
 501
 502         return "";
 503 }
 504
 505 sub expand_tabs {
 506         my ($str) = @_;
 507
 508         my $res = '';
 509         my $n = 0;
 510         for my $c (split(//, $str)) {
 511                 if ($c eq "\t") {
 512                         $res .= ' ';
 513                         $n++;
 514                         for (; ($n % 8) != 0; $n++) {
 515                                 $res .= ' ';
 516                         }
 517                         next;
 518                 }
 519                 $res .= $c;
 520                 $n++;
 521         }
 522
 523         return $res;
 524 }
 525 sub copy_spacing {
 526         (my $res = shift) =~ tr/\t/ /c;
 527         return $res;
 528 }
 529
 530 sub line_stats {
 531         my ($line) = @_;
 532
 533         # Drop the diff line leader and expand tabs
 534         $line =~ s/^.//;
 535         $line = expand_tabs($line);
 536
 537         # Pick the indent from the front of the line.
 538         my ($white) = ($line =~ /^(\s*)/);
 539
 540         return (length($line), length($white));
 541 }
 542
 543 my $sanitise_quote = '';
 544
 545 sub sanitise_line_reset {
 546         my ($in_comment) = @_;
 547
 548         if ($in_comment) {
 549                 $sanitise_quote = '*/';
 550         } else {
 551                 $sanitise_quote = '';
 552         }
 553 }
 554 sub sanitise_line {
 555         my ($line) = @_;
 556
 557         my $res = '';
 558         my $l = '';
 559
 560         my $qlen = 0;
 561         my $off = 0;
 562         my $c;
 563
 564         # Always copy over the diff marker.
 565         $res = substr($line, 0, 1);
 566
 567         for ($off = 1; $off < length($line); $off++) {
 568                 $c = substr($line, $off, 1);
 569
 570                 # Comments we are wacking completly including the begin
 571                 # and end, all to $;.
 572                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '/*') {
 573                         $sanitise_quote = '*/';
 574
 575                         substr($res, $off, 2, "$;$;");
 576                         $off++;
 577                         next;
 578                 }
 579                 if ($sanitise_quote eq '*/' && substr($line, $off, 2) eq '*/') {
 580                         $sanitise_quote = '';
 581                         substr($res, $off, 2, "$;$;");
 582                         $off++;
 583                         next;
 584                 }
 585                 if ($sanitise_quote eq '' && substr($line, $off, 2) eq '//') {
 586                         $sanitise_quote = '//';
 587
 588                         substr($res, $off, 2, $sanitise_quote);
 589                         $off++;
 590                         next;
 591                 }
 592
 593                 # A \ in a string means ignore the next character.
 594                 if (($sanitise_quote eq "'" || $sanitise_quote eq '"') &&
 595                     $c eq "\\") {
 596                         substr($res, $off, 2, 'XX');
 597                         $off++;
 598                         next;
 599                 }
 600                 # Regular quotes.
 601                 if ($c eq "'" || $c eq '"') {
 602                         if ($sanitise_quote eq '') {
 603                                 $sanitise_quote = $c;
 604
 605                                 substr($res, $off, 1, $c);
 606                                 next;
 607                         } elsif ($sanitise_quote eq $c) {
 608                                 $sanitise_quote = '';
 609                         }
 610                 }
 611
 612                 #print "c<$c> SQ<$sanitise_quote>\n";
 613                 if ($off != 0 && $sanitise_quote eq '*/' && $c ne "\t") {
 614                         substr($res, $off, 1, $;);
 615                 } elsif ($off != 0 && $sanitise_quote eq '//' && $c ne "\t") {
 616                         substr($res, $off, 1, $;);
 617                 } elsif ($off != 0 && $sanitise_quote && $c ne "\t") {
 618                         substr($res, $off, 1, 'X');
 619                 } else {
 620                         substr($res, $off, 1, $c);
 621                 }
 622         }
 623
 624         if ($sanitise_quote eq '//') {
 625                 $sanitise_quote = '';
 626         }
 627
 628         # The pathname on a #include may be surrounded by '<' and '>'.
 629         if ($res =~ /^.\s*\#\s*include\s+\<(.*)\>/) {
 630                 my $clean = 'X' x length($1);
 631                 $res =~ s@\<.*\>@<$clean>@;
 632
 633         # The whole of a #error is a string.
 634         } elsif ($res =~ /^.\s*\#\s*(?:error|warning)\s+(.*)\b/) {
 635                 my $clean = 'X' x length($1);
 636                 $res =~ s@(\#\s*(?:error|warning)\s+).*@$1$clean@;
 637         }
 638
 639         return $res;
 640 }
 641
 642 sub ctx_statement_block {
 643         my ($linenr, $remain, $off) = @_;
 644         my $line = $linenr - 1;
 645         my $blk = '';
 646         my $soff = $off;
 647         my $coff = $off - 1;
 648         my $coff_set = 0;
 649
 650         my $loff = 0;
 651
 652         my $type = '';
 653         my $level = 0;
 654         my @stack = ();
 655         my $p;
 656         my $c;
 657         my $len = 0;
 658
 659         my $remainder;
 660         while (1) {
 661                 @stack = (['', 0]) if ($#stack == -1);
 662
 663                 #warn "CSB: blk<$blk> remain<$remain>\n";
 664                 # If we are about to drop off the end, pull in more
 665                 # context.
 666                 if ($off >= $len) {
 667                         for (; $remain > 0; $line++) {
 668                                 last if (!defined $lines[$line]);
 669                                 next if ($lines[$line] =~ /^-/);
 670                                 $remain--;
 671                                 $loff = $len;
 672                                 $blk .= $lines[$line] . "\n";
 673                                 $len = length($blk);
 674                                 $line++;
 675                                 last;
 676                         }
 677                         # Bail if there is no further context.
 678                         #warn "CSB: blk<$blk> off<$off> len<$len>\n";
 679                         if ($off >= $len) {
 680                                 last;
 681                         }
 682                 }
 683                 $p = $c;
 684                 $c = substr($blk, $off, 1);
 685                 $remainder = substr($blk, $off);
 686
 687                 #warn "CSB: c<$c> type<$type> level<$level> remainder<$remainder> coff_set<$coff_set>\n";
 688
 689                 # Handle nested #if/#else.
 690                 if ($remainder =~ /^#\s*(?:ifndef|ifdef|if)\s/) {
 691                         push(@stack, [ $type, $level ]);
 692                 } elsif ($remainder =~ /^#\s*(?:else|elif)\b/) {
 693                         ($type, $level) = @{$stack[$#stack - 1]};
 694                 } elsif ($remainder =~ /^#\s*endif\b/) {
 695                         ($type, $level) = @{pop(@stack)};
 696                 }
 697
 698                 # Statement ends at the ';' or a close '}' at the
 699                 # outermost level.
 700                 if ($level == 0 && $c eq ';') {
 701                         last;
 702                 }
 703
 704                 # An else is really a conditional as long as its not else if
 705                 if ($level == 0 && $coff_set == 0 &&
 706                                 (!defined($p) || $p =~ /(?:\s|\}|\+)/) &&
 707                                 $remainder =~ /^(else)(?:\s|{)/ &&
 708                                 $remainder !~ /^else\s+if\b/) {
 709                         $coff = $off + length($1) - 1;
 710                         $coff_set = 1;
 711                         #warn "CSB: mark coff<$coff> soff<$soff> 1<$1>\n";
 712                         #warn "[" . substr($blk, $soff, $coff - $soff + 1) . "]\n";
 713                 }
 714
 715                 if (($type eq '' || $type eq '(') && $c eq '(') {
 716                         $level++;
 717                         $type = '(';
 718                 }
 719                 if ($type eq '(' && $c eq ')') {
 720                         $level--;
 721                         $type = ($level != 0)? '(' : '';
 722
 723                         if ($level == 0 && $coff < $soff) {
 724                                 $coff = $off;
 725                                 $coff_set = 1;
 726                                 #warn "CSB: mark coff<$coff>\n";
 727                         }
 728                 }
 729                 if (($type eq '' || $type eq '{') && $c eq '{') {
 730                         $level++;
 731                         $type = '{';
 732                 }
 733                 if ($type eq '{' && $c eq '}') {
 734                         $level--;
 735                         $type = ($level != 0)? '{' : '';
 736
 737                         if ($level == 0) {
 738                                 if (substr($blk, $off + 1, 1) eq ';') {
 739                                         $off++;
 740                                 }
 741                                 last;
 742                         }
 743                 }
 744                 $off++;
 745         }
 746         # We are truly at the end, so shuffle to the next line.
 747         if ($off == $len) {
 748                 $loff = $len + 1;
 749                 $line++;
 750                 $remain--;
 751         }
 752
 753         my $statement = substr($blk, $soff, $off - $soff + 1);
 754         my $condition = substr($blk, $soff, $coff - $soff + 1);
 755
 756         #warn "STATEMENT<$statement>\n";
 757         #warn "CONDITION<$condition>\n";
 758
 759         #print "coff<$coff> soff<$off> loff<$loff>\n";
 760
 761         return ($statement, $condition,
 762                         $line, $remain + 1, $off - $loff + 1, $level);
 763 }
 764
 765 sub statement_lines {
 766         my ($stmt) = @_;
 767
 768         # Strip the diff line prefixes and rip blank lines at start and end.
 769         $stmt =~ s/(^|\n)./$1/g;
 770         $stmt =~ s/^\s*//;
 771         $stmt =~ s/\s*$//;
 772
 773         my @stmt_lines = ($stmt =~ /\n/g);
 774
 775         return $#stmt_lines + 2;
 776 }
 777
 778 sub statement_rawlines {
 779         my ($stmt) = @_;
 780
 781         my @stmt_lines = ($stmt =~ /\n/g);
 782
 783         return $#stmt_lines + 2;
 784 }
 785
 786 sub statement_block_size {
 787         my ($stmt) = @_;
 788
 789         $stmt =~ s/(^|\n)./$1/g;
 790         $stmt =~ s/^\s*{//;
 791         $stmt =~ s/}\s*$//;
 792         $stmt =~ s/^\s*//;
 793         $stmt =~ s/\s*$//;
 794
 795         my @stmt_lines = ($stmt =~ /\n/g);
 796         my @stmt_statements = ($stmt =~ /;/g);
 797
 798         my $stmt_lines = $#stmt_lines + 2;
 799         my $stmt_statements = $#stmt_statements + 1;
 800
 801         if ($stmt_lines > $stmt_statements) {
 802                 return $stmt_lines;
 803         } else {
 804                 return $stmt_statements;
 805         }
 806 }
 807
 808 sub ctx_statement_full {
 809         my ($linenr, $remain, $off) = @_;
 810         my ($statement, $condition, $level);
 811
 812         my (@chunks);
 813
 814         # Grab the first conditional/block pair.
 815         ($statement, $condition, $linenr, $remain, $off, $level) =
 816                                 ctx_statement_block($linenr, $remain, $off);
 817         #print "F: c<$condition> s<$statement> remain<$remain>\n";
 818         push(@chunks, [ $condition, $statement ]);
 819         if (!($remain > 0 && $condition =~ /^\s*(?:\n[+-])?\s*(?:if|else|do)\b/s)) {
 820                 return ($level, $linenr, @chunks);
 821         }
 822
 823         # Pull in the following conditional/block pairs and see if they
 824         # could continue the statement.
 825         for (;;) {
 826                 ($statement, $condition, $linenr, $remain, $off, $level) =
 827                                 ctx_statement_block($linenr, $remain, $off);
 828                 #print "C: c<$condition> s<$statement> remain<$remain>\n";
 829                 last if (!($remain > 0 && $condition =~ /^(?:\s*\n[+-])*\s*(?:else|do)\b/s));
 830                 #print "C: push\n";
 831                 push(@chunks, [ $condition, $statement ]);
 832         }
 833
 834         return ($level, $linenr, @chunks);
 835 }
 836
 837 sub ctx_block_get {
 838         my ($linenr, $remain, $outer, $open, $close, $off) = @_;
 839         my $line;
 840         my $start = $linenr - 1;
 841         my $blk = '';
 842         my @o;
 843         my @c;
 844         my @res = ();
 845
 846         my $level = 0;
 847         my @stack = ($level);
 848         for ($line = $start; $remain > 0; $line++) {
 849                 next if ($rawlines[$line] =~ /^-/);
 850                 $remain--;
 851
 852                 $blk .= $rawlines[$line];
 853
 854                 # Handle nested #if/#else.
 855                 if ($lines[$line] =~ /^.\s*#\s*(?:ifndef|ifdef|if)\s/) {
 856                         push(@stack, $level);
 857                 } elsif ($lines[$line] =~ /^.\s*#\s*(?:else|elif)\b/) {
 858                         $level = $stack[$#stack - 1];
 859                 } elsif ($lines[$line] =~ /^.\s*#\s*endif\b/) {
 860                         $level = pop(@stack);
 861                 }
 862
 863                 foreach my $c (split(//, $lines[$line])) {
 864                         ##print "C<$c>L<$level><$open$close>O<$off>\n";
 865                         if ($off > 0) {
 866                                 $off--;
 867                                 next;
 868                         }
 869
 870                         if ($c eq $close && $level > 0) {
 871                                 $level--;
 872                                 last if ($level == 0);
 873                         } elsif ($c eq $open) {
 874                                 $level++;
 875                         }
 876                 }
 877
 878                 if (!$outer || $level <= 1) {
 879                         push(@res, $rawlines[$line]);
 880                 }
 881
 882                 last if ($level == 0);
 883         }
 884
 885         return ($level, @res);
 886 }
 887 sub ctx_block_outer {
 888         my ($linenr, $remain) = @_;
 889
 890         my ($level, @r) = ctx_block_get($linenr, $remain, 1, '{', '}', 0);
 891         return @r;
 892 }
 893 sub ctx_block {
 894         my ($linenr, $remain) = @_;
 895
 896         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '{', '}', 0);
 897         return @r;
 898 }
 899 sub ctx_statement {
 900         my ($linenr, $remain, $off) = @_;
 901
 902         my ($level, @r) = ctx_block_get($linenr, $remain, 0, '(', ')', $off);
 903         return @r;
 904 }
 905 sub ctx_block_level {
 906         my ($linenr, $remain) = @_;
 907
 908         return ctx_block_get($linenr, $remain, 0, '{', '}', 0);
 909 }
 910 sub ctx_statement_level {
 911         my ($linenr, $remain, $off) = @_;
 912
 913         return ctx_block_get($linenr, $remain, 0, '(', ')', $off);
 914 }
 915
 916 sub ctx_locate_comment {
 917         my ($first_line, $end_line) = @_;
 918
 919         # Catch a comment on the end of the line itself.
 920         my ($current_comment) = ($rawlines[$end_line - 1] =~ m@.*(/\*.*\*/)\s*(?:\\\s*)?$@);
 921         return $current_comment if (defined $current_comment);
 922
 923         # Look through the context and try and figure out if there is a
 924         # comment.
 925         my $in_comment = 0;
 926         $current_comment = '';
 927         for (my $linenr = $first_line; $linenr < $end_line; $linenr++) {
 928                 my $line = $rawlines[$linenr - 1];
 929                 #warn "           $line\n";
 930                 if ($linenr == $first_line and $line =~ m@^.\s*\*@) {
 931                         $in_comment = 1;
 932                 }
 933                 if ($line =~ m@/\*@) {
 934                         $in_comment = 1;
 935                 }
 936                 if (!$in_comment && $current_comment ne '') {
 937                         $current_comment = '';
 938                 }
 939                 $current_comment .= $line . "\n" if ($in_comment);
 940                 if ($line =~ m@\*/@) {
 941                         $in_comment = 0;
 942                 }
 943         }
 944
 945         chomp($current_comment);
 946         return($current_comment);
 947 }
 948 sub ctx_has_comment {
 949         my ($first_line, $end_line) = @_;
 950         my $cmt = ctx_locate_comment($first_line, $end_line);
 951
 952         ##print "LINE: $rawlines[$end_line - 1 ]\n";
 953         ##print "CMMT: $cmt\n";
 954
 955         return ($cmt ne '');
 956 }
 957
 958 sub raw_line {
 959         my ($linenr, $cnt) = @_;
 960
 961         my $offset = $linenr - 1;
 962         $cnt++;
 963
 964         my $line;
 965         while ($cnt) {
 966                 $line = $rawlines[$offset++];
 967                 next if (defined($line) && $line =~ /^-/);
 968                 $cnt--;
 969         }
 970
 971         return $line;
 972 }
 973
 974 sub cat_vet {
 975         my ($vet) = @_;
 976         my ($res, $coded);
 977
 978         $res = '';
 979         while ($vet =~ /([^[:cntrl:]]*)([[:cntrl:]]|$)/g) {
 980                 $res .= $1;
 981                 if ($2 ne '') {
 982                         $coded = sprintf("^%c", unpack('C', $2) + 64);
 983                         $res .= $coded;
 984                 }
 985         }
 986         $res =~ s/$/\$/;
 987
 988         return $res;
 989 }
 990
 991 my $av_preprocessor = 0;
 992 my $av_pending;
 993 my @av_paren_type;
 994 my $av_pend_colon;
 995
 996 sub annotate_reset {
 997         $av_preprocessor = 0;
 998         $av_pending = '_';
 999         @av_paren_type = ('E');
1000         $av_pend_colon = 'O';
1001 }
1002
1003 sub annotate_values {
1004         my ($stream, $type) = @_;
1005
1006         my $res;
1007         my $var = '_' x length($stream);
1008         my $cur = $stream;
1009
1010         print "$stream\n" if ($dbg_values > 1);
1011
1012         while (length($cur)) {
1013                 @av_paren_type = ('E') if ($#av_paren_type < 0);
1014                 print " <" . join('', @av_paren_type) .
1015                                 "> <$type> <$av_pending>" if ($dbg_values > 1);
1016                 if ($cur =~ /^(\s+)/o) {
1017                         print "WS($1)\n" if ($dbg_values > 1);
1018                         if ($1 =~ /\n/ && $av_preprocessor) {
1019                                 $type = pop(@av_paren_type);
1020                                 $av_preprocessor = 0;
1021                         }
1022
1023                 } elsif ($cur =~ /^(\(\s*$Type\s*)\)/ && $av_pending eq '_') {
1024                         print "CAST($1)\n" if ($dbg_values > 1);
1025                         push(@av_paren_type, $type);
1026                         $type = 'C';
1027
1028                 } elsif ($cur =~ /^($Type)\s*(?:$Ident|,|\)|\(|\s*$)/) {
1029                         print "DECLARE($1)\n" if ($dbg_values > 1);
1030                         $type = 'T';
1031
1032                 } elsif ($cur =~ /^($Modifier)\s*/) {
1033                         print "MODIFIER($1)\n" if ($dbg_values > 1);
1034                         $type = 'T';
1035
1036                 } elsif ($cur =~ /^(\#\s*define\s*$Ident)(\(?)/o) {
1037                         print "DEFINE($1,$2)\n" if ($dbg_values > 1);
1038                         $av_preprocessor = 1;
1039                         push(@av_paren_type, $type);
1040                         if ($2 ne '') {
1041                                 $av_pending = 'N';
1042                         }
1043                         $type = 'E';
1044
1045                 } elsif ($cur =~ /^(\#\s*(?:undef\s*$Ident|include\b))/o) {
1046                         print "UNDEF($1)\n" if ($dbg_values > 1);
1047                         $av_preprocessor = 1;
1048                         push(@av_paren_type, $type);
1049
1050                 } elsif ($cur =~ /^(\#\s*(?:ifdef|ifndef|if))/o) {
1051                         print "PRE_START($1)\n" if ($dbg_values > 1);
1052                         $av_preprocessor = 1;
1053
1054                         push(@av_paren_type, $type);
1055                         push(@av_paren_type, $type);
1056                         $type = 'E';
1057
1058                 } elsif ($cur =~ /^(\#\s*(?:else|elif))/o) {
1059                         print "PRE_RESTART($1)\n" if ($dbg_values > 1);
1060                         $av_preprocessor = 1;
1061
1062                         push(@av_paren_type, $av_paren_type[$#av_paren_type]);
1063
1064                         $type = 'E';
1065
1066                 } elsif ($cur =~ /^(\#\s*(?:endif))/o) {
1067                         print "PRE_END($1)\n" if ($dbg_values > 1);
1068
1069                         $av_preprocessor = 1;
1070
1071                         # Assume all arms of the conditional end as this
1072                         # one does, and continue as if the #endif was not here.
1073                         pop(@av_paren_type);
1074                         push(@av_paren_type, $type);
1075                         $type = 'E';
1076
1077                 } elsif ($cur =~ /^(\\\n)/o) {
1078                         print "PRECONT($1)\n" if ($dbg_values > 1);
1079
1080                 } elsif ($cur =~ /^(__attribute__)\s*\(?/o) {
1081                         print "ATTR($1)\n" if ($dbg_values > 1);
1082                         $av_pending = $type;
1083                         $type = 'N';
1084
1085                 } elsif ($cur =~ /^(sizeof)\s*(\()?/o) {
1086                         print "SIZEOF($1)\n" if ($dbg_values > 1);
1087                         if (defined $2) {
1088                                 $av_pending = 'V';
1089                         }
1090                         $type = 'N';
1091
1092                 } elsif ($cur =~ /^(if|while|for)\b/o) {
1093                         print "COND($1)\n" if ($dbg_values > 1);
1094                         $av_pending = 'E';
1095                         $type = 'N';
1096
1097                 } elsif ($cur =~/^(case)/o) {
1098                         print "CASE($1)\n" if ($dbg_values > 1);
1099                         $av_pend_colon = 'C';
1100                         $type = 'N';
1101
1102                 } elsif ($cur =~/^(return|else|goto|typeof|__typeof__)\b/o) {
1103                         print "KEYWORD($1)\n" if ($dbg_values > 1);
1104                         $type = 'N';
1105
1106                 } elsif ($cur =~ /^(\()/o) {
1107                         print "PAREN('$1')\n" if ($dbg_values > 1);
1108                         push(@av_paren_type, $av_pending);
1109                         $av_pending = '_';
1110                         $type = 'N';
1111
1112                 } elsif ($cur =~ /^(\))/o) {
1113                         my $new_type = pop(@av_paren_type);
1114                         if ($new_type ne '_') {
1115                                 $type = $new_type;
1116                                 print "PAREN('$1') -> $type\n"
1117                                                         if ($dbg_values > 1);
1118                         } else {
1119                                 print "PAREN('$1')\n" if ($dbg_values > 1);
1120                         }
1121
1122                 } elsif ($cur =~ /^($Ident)\s*\(/o) {
1123                         print "FUNC($1)\n" if ($dbg_values > 1);
1124                         $type = 'V';
1125                         $av_pending = 'V';
1126
1127                 } elsif ($cur =~ /^($Ident\s*):(?:\s*\d+\s*(,|=|;))?/) {
1128                         if (defined $2 && $type eq 'C' || $type eq 'T') {
1129                                 $av_pend_colon = 'B';
1130                         } elsif ($type eq 'E') {
1131                                 $av_pend_colon = 'L';
1132                         }
1133                         print "IDENT_COLON($1,$type>$av_pend_colon)\n" if ($dbg_values > 1);
1134                         $type = 'V';
1135
1136                 } elsif ($cur =~ /^($Ident|$Constant)/o) {
1137                         print "IDENT($1)\n" if ($dbg_values > 1);
1138                         $type = 'V';
1139
1140                 } elsif ($cur =~ /^($Assignment)/o) {
1141                         print "ASSIGN($1)\n" if ($dbg_values > 1);
1142                         $type = 'N';
1143
1144                 } elsif ($cur =~/^(;|{|})/) {
1145                         print "END($1)\n" if ($dbg_values > 1);
1146                         $type = 'E';
1147                         $av_pend_colon = 'O';
1148
1149                 } elsif ($cur =~/^(,)/) {
1150                         print "COMMA($1)\n" if ($dbg_values > 1);
1151                         $type = 'C';
1152
1153                 } elsif ($cur =~ /^(\?)/o) {
1154                         print "QUESTION($1)\n" if ($dbg_values > 1);
1155                         $type = 'N';
1156
1157                 } elsif ($cur =~ /^(:)/o) {
1158                         print "COLON($1,$av_pend_colon)\n" if ($dbg_values > 1);
1159
1160                         substr($var, length($res), 1, $av_pend_colon);
1161                         if ($av_pend_colon eq 'C' || $av_pend_colon eq 'L') {
1162                                 $type = 'E';
1163                         } else {
1164                                 $type = 'N';
1165                         }
1166                         $av_pend_colon = 'O';
1167
1168                 } elsif ($cur =~ /^(\[)/o) {
1169                         print "CLOSE($1)\n" if ($dbg_values > 1);
1170                         $type = 'N';
1171
1172                 } elsif ($cur =~ /^(-(?![->])|\+(?!\+)|\*|\&\&|\&)/o) {
1173                         my $variant;
1174
1175                         print "OPV($1)\n" if ($dbg_values > 1);
1176                         if ($type eq 'V') {
1177                                 $variant = 'B';
1178                         } else {
1179                                 $variant = 'U';
1180                         }
1181
1182                         substr($var, length($res), 1, $variant);
1183                         $type = 'N';
1184
1185                 } elsif ($cur =~ /^($Operators)/o) {
1186                         print "OP($1)\n" if ($dbg_values > 1);
1187                         if ($1 ne '++' && $1 ne '--') {
1188                                 $type = 'N';
1189                         }
1190
1191                 } elsif ($cur =~ /(^.)/o) {
1192                         print "C($1)\n" if ($dbg_values > 1);
1193                 }
1194                 if (defined $1) {
1195                         $cur = substr($cur, length($1));
1196                         $res .= $type x length($1);
1197                 }
1198         }
1199
1200         return ($res, $var);
1201 }
1202
1203 sub possible {
1204         my ($possible, $line) = @_;
1205         my $notPermitted = qr{(?:
1206                 ^(?:
1207                         $Modifier|
1208                         $Storage|
1209                         $Type|
1210                         DEFINE_\S+
1211                 )$|
1212                 ^(?:
1213                         goto|
1214                         return|
1215                         case|
1216                         else|
1217                         asm|__asm__|
1218                         do
1219                 )(?:\s|$)|
1220                 ^(?:typedef|struct|enum)\b
1221             )}x;
1222         warn "CHECK<$possible> ($line)\n" if ($dbg_possible > 2);
1223         if ($possible !~ $notPermitted) {
1224                 # Check for modifiers.
1225                 $possible =~ s/\s*$Storage\s*//g;
1226                 $possible =~ s/\s*$Sparse\s*//g;
1227                 if ($possible =~ /^\s*$/) {
1228
1229                 } elsif ($possible =~ /\s/) {
1230                         $possible =~ s/\s*$Type\s*//g;
1231                         for my $modifier (split(' ', $possible)) {
1232                                 if ($modifier !~ $notPermitted) {
1233                                         warn "MODIFIER: $modifier ($possible) ($line)\n" if ($dbg_possible);
1234                                         push(@modifierList, $modifier);
1235                                 }
1236                         }
1237
1238                 } else {
1239                         warn "POSSIBLE: $possible ($line)\n" if ($dbg_possible);
1240                         push(@typeList, $possible);
1241                 }
1242                 build_types();
1243         } else {
1244                 warn "NOTPOSS: $possible ($line)\n" if ($dbg_possible > 1);
1245         }
1246 }
1247
1248 my $prefix = '';
1249
1250 sub show_type {
1251        return !defined $ignore_type{$_[0]};
1252 }
1253
1254 sub report {
1255         if (!show_type($_[1]) ||
1256             (defined $tst_only && $_[2] !~ /\Q$tst_only\E/)) {
1257                 return 0;
1258         }
1259         my $line;
1260         if ($show_types) {
1261                 $line = "$prefix$_[0]:$_[1]: $_[2]\n";
1262         } else {
1263                 $line = "$prefix$_[0]: $_[2]\n";
1264         }
1265         $line = (split('\n', $line))[0] . "\n" if ($terse);
1266
1267         push(our @report, $line);
1268
1269         return 1;
1270 }
1271 sub report_dump {
1272         our @report;
1273 }
1274
1275 sub ERROR {
1276         if (report("ERROR", $_[0], $_[1])) {
1277                 our $clean = 0;
1278                 our $cnt_error++;
1279         }
1280 }
1281 sub WARN {
1282         if (report("WARNING", $_[0], $_[1])) {
1283                 our $clean = 0;
1284                 our $cnt_warn++;
1285         }
1286 }
1287 sub CHK {
1288         if ($check && report("CHECK", $_[0], $_[1])) {
1289                 our $clean = 0;
1290                 our $cnt_chk++;
1291         }
1292 }
1293
1294 sub check_absolute_file {
1295         my ($absolute, $herecurr) = @_;
1296         my $file = $absolute;
1297
1298         ##print "absolute<$absolute>\n";
1299
1300         # See if any suffix of this path is a path within the tree.
1301         while ($file =~ s@^[^/]*/@@) {
1302                 if (-f "$root/$file") {
1303                         ##print "file<$file>\n";
1304                         last;
1305                 }
1306         }
1307         if (! -f _)  {
1308                 return 0;
1309         }
1310
1311         # It is, so see if the prefix is acceptable.
1312         my $prefix = $absolute;
1313         substr($prefix, -length($file)) = '';
1314
1315         ##print "prefix<$prefix>\n";
1316         if ($prefix ne ".../") {
1317                 WARN("USE_RELATIVE_PATH",
1318                      "use relative pathname instead of absolute in changelog text\n" . $herecurr);
1319         }
1320 }
1321
1322 sub process {
1323         my $filename = shift;
1324
1325         my $linenr=0;
1326         my $prevline="";
1327         my $prevrawline="";
1328         my $stashline="";
1329         my $stashrawline="";
1330
1331         my $length;
1332         my $indent;
1333         my $previndent=0;
1334         my $stashindent=0;
1335
1336         our $clean = 1;
1337         my $signoff = 0;
1338         my $is_patch = 0;
1339
1340         my $in_header_lines = 1;
1341         my $in_commit_log = 0;          #Scanning lines before patch
1342
1343         our @report = ();
1344         our $cnt_lines = 0;
1345         our $cnt_error = 0;
1346         our $cnt_warn = 0;
1347         our $cnt_chk = 0;
1348
1349         # Trace the real file/line as we go.
1350         my $realfile = '';
1351         my $realline = 0;
1352         my $realcnt = 0;
1353         my $here = '';
1354         my $in_comment = 0;
1355         my $comment_edge = 0;
1356         my $first_line = 0;
1357         my $p1_prefix = '';
1358
1359         my $prev_values = 'E';
1360
1361         # suppression flags
1362         my %suppress_ifbraces;
1363         my %suppress_whiletrailers;
1364         my %suppress_export;
1365
1366         # Pre-scan the patch sanitizing the lines.
1367         # Pre-scan the patch looking for any __setup documentation.
1368         #
1369         my @setup_docs = ();
1370         my $setup_docs = 0;
1371
1372         sanitise_line_reset();
1373         my $line;
1374         foreach my $rawline (@rawlines) {
1375                 $linenr++;
1376                 $line = $rawline;
1377
1378                 if ($rawline=~/^\+\+\+\s+(\S+)/) {
1379                         $setup_docs = 0;
1380                         if ($1 =~ m@Documentation/kernel-parameters.txt$@) {
1381                                 $setup_docs = 1;
1382                         }
1383                         #next;
1384                 }
1385                 if ($rawline=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1386                         $realline=$1-1;
1387                         if (defined $2) {
1388                                 $realcnt=$3+1;
1389                         } else {
1390                                 $realcnt=1+1;
1391                         }
1392                         $in_comment = 0;
1393
1394                         # Guestimate if this is a continuing comment.  Run
1395                         # the context looking for a comment "edge".  If this
1396                         # edge is a close comment then we must be in a comment
1397                         # at context start.
1398                         my $edge;
1399                         my $cnt = $realcnt;
1400                         for (my $ln = $linenr + 1; $cnt > 0; $ln++) {
1401                                 next if (defined $rawlines[$ln - 1] &&
1402                                          $rawlines[$ln - 1] =~ /^-/);
1403                                 $cnt--;
1404                                 #print "RAW<$rawlines[$ln - 1]>\n";
1405                                 last if (!defined $rawlines[$ln - 1]);
1406                                 if ($rawlines[$ln - 1] =~ m@(/\*|\*/)@ &&
1407                                     $rawlines[$ln - 1] !~ m@"[^"]*(?:/\*|\*/)[^"]*"@) {
1408                                         ($edge) = $1;
1409                                         last;
1410                                 }
1411                         }
1412                         if (defined $edge && $edge eq '*/') {
1413                                 $in_comment = 1;
1414                         }
1415
1416                         # Guestimate if this is a continuing comment.  If this
1417                         # is the start of a diff block and this line starts
1418                         # ' *' then it is very likely a comment.
1419                         if (!defined $edge &&
1420                             $rawlines[$linenr] =~ m@^.\s*(?:\*\*+| \*)(?:\s|$)@)
1421                         {
1422                                 $in_comment = 1;
1423                         }
1424
1425                         ##print "COMMENT:$in_comment edge<$edge> $rawline\n";
1426                         sanitise_line_reset($in_comment);
1427
1428                 } elsif ($realcnt && $rawline =~ /^(?:\+| |$)/) {
1429                         # Standardise the strings and chars within the input to
1430                         # simplify matching -- only bother with positive lines.
1431                         $line = sanitise_line($rawline);
1432                 }
1433                 push(@lines, $line);
1434
1435                 if ($realcnt > 1) {
1436                         $realcnt-- if ($line =~ /^(?:\+| |$)/);
1437                 } else {
1438                         $realcnt = 0;
1439                 }
1440
1441                 #print "==>$rawline\n";
1442                 #print "-->$line\n";
1443
1444                 if ($setup_docs && $line =~ /^\+/) {
1445                         push(@setup_docs, $line);
1446                 }
1447         }
1448
1449         $prefix = '';
1450
1451         $realcnt = 0;
1452         $linenr = 0;
1453         foreach my $line (@lines) {
1454                 $linenr++;
1455
1456                 my $rawline = $rawlines[$linenr - 1];
1457
1458 #extract the line range in the file after the patch is applied
1459                 if ($line=~/^\@\@ -\d+(?:,\d+)? \+(\d+)(,(\d+))? \@\@/) {
1460                         $is_patch = 1;
1461                         $first_line = $linenr + 1;
1462                         $realline=$1-1;
1463                         if (defined $2) {
1464                                 $realcnt=$3+1;
1465                         } else {
1466                                 $realcnt=1+1;
1467                         }
1468                         annotate_reset();
1469                         $prev_values = 'E';
1470
1471                         %suppress_ifbraces = ();
1472                         %suppress_whiletrailers = ();
1473                         %suppress_export = ();
1474                         next;
1475
1476 # track the line number as we move through the hunk, note that
1477 # new versions of GNU diff omit the leading space on completely
1478 # blank context lines so we need to count that too.
1479                 } elsif ($line =~ /^( |\+|$)/) {
1480                         $realline++;
1481                         $realcnt-- if ($realcnt != 0);
1482
1483                         # Measure the line length and indent.
1484                         ($length, $indent) = line_stats($rawline);
1485
1486                         # Track the previous line.
1487                         ($prevline, $stashline) = ($stashline, $line);
1488                         ($previndent, $stashindent) = ($stashindent, $indent);
1489                         ($prevrawline, $stashrawline) = ($stashrawline, $rawline);
1490
1491                         #warn "line<$line>\n";
1492
1493                 } elsif ($realcnt == 1) {
1494                         $realcnt--;
1495                 }
1496
1497                 my $hunk_line = ($realcnt != 0);
1498
1499 #make up the handle for any error we report on this line
1500                 $prefix = "$filename:$realline: " if ($emacs && $file);
1501                 $prefix = "$filename:$linenr: " if ($emacs && !$file);
1502
1503                 $here = "#$linenr: " if (!$file);
1504                 $here = "#$realline: " if ($file);
1505
1506                 # extract the filename as it passes
1507                 if ($line =~ /^diff --git.*?(\S+)$/) {
1508                         $realfile = $1;
1509                         $realfile =~ s@^([^/]*)/@@;
1510                 } elsif ($line =~ /^\+\+\+\s+(\S+)/) {
1511                         $realfile = $1;
1512                         $realfile =~ s@^([^/]*)/@@;
1513
1514                         $p1_prefix = $1;
1515                         if (!$file && $tree && $p1_prefix ne '' &&
1516                             -e "$root/$p1_prefix") {
1517                                 WARN("PATCH_PREFIX",
1518                                      "patch prefix '$p1_prefix' exists, appears to be a -p0 patch\n");
1519                         }
1520
1521                         if ($realfile =~ m@^include/asm/@) {
1522                                 ERROR("MODIFIED_INCLUDE_ASM",
1523                                       "do not modify files in include/asm, change architecture specific files in include/asm-<architecture>\n" . "$here$rawline\n");
1524                         }
1525                         next;
1526                 }
1527
1528                 $here .= "FILE: $realfile:$realline:" if ($realcnt != 0);
1529
1530                 my $hereline = "$here\n$rawline\n";
1531                 my $herecurr = "$here\n$rawline\n";
1532                 my $hereprev = "$here\n$prevrawline\n$rawline\n";
1533
1534                 $cnt_lines++ if ($realcnt != 0);
1535
1536 # Check for incorrect file permissions
1537                 if ($line =~ /^new (file )?mode.*[7531]\d{0,2}$/) {
1538                         my $permhere = $here . "FILE: $realfile\n";
1539                         if ($realfile =~ /(Makefile|Kconfig|\.c|\.h|\.S|\.tmpl)$/) {
1540                                 ERROR("EXECUTE_PERMISSIONS",
1541                                       "do not set execute permissions for source files\n" . $permhere);
1542                         }
1543                 }
1544
1545 # Check the patch for a signoff:
1546                 if ($line =~ /^\s*signed-off-by:/i) {
1547                         $signoff++;
1548                         $in_commit_log = 0;
1549                 }
1550
1551 # Check signature styles
1552                 if ($line =~ /^(\s*)($signature_tags)(\s*)(.*)/) {
1553                         my $space_before = $1;
1554                         my $sign_off = $2;
1555                         my $space_after = $3;
1556                         my $email = $4;
1557                         my $ucfirst_sign_off = ucfirst(lc($sign_off));
1558
1559                         if (defined $space_before && $space_before ne "") {
1560                                 WARN("BAD_SIGN_OFF",
1561                                      "Do not use whitespace before $ucfirst_sign_off\n" . $herecurr);
1562                         }
1563                         if ($sign_off =~ /-by:$/i && $sign_off ne $ucfirst_sign_off) {
1564                                 WARN("BAD_SIGN_OFF",
1565                                      "'$ucfirst_sign_off' is the preferred signature form\n" . $herecurr);
1566                         }
1567                         if (!defined $space_after || $space_after ne " ") {
1568                                 WARN("BAD_SIGN_OFF",
1569                                      "Use a single space after $ucfirst_sign_off\n" . $herecurr);
1570                         }
1571
1572                         my ($email_name, $email_address, $comment) = parse_email($email);
1573                         my $suggested_email = format_email(($email_name, $email_address));
1574                         if ($suggested_email eq "") {
1575                                 ERROR("BAD_SIGN_OFF",
1576                                       "Unrecognized email address: '$email'\n" . $herecurr);
1577                         } else {
1578                                 my $dequoted = $suggested_email;
1579                                 $dequoted =~ s/^"//;
1580                                 $dequoted =~ s/" </ </;
1581                                 # Don't force email to have quotes
1582                                 # Allow just an angle bracketed address
1583                                 if ("$dequoted$comment" ne $email &&
1584                                     "<$email_address>$comment" ne $email &&
1585                                     "$suggested_email$comment" ne $email) {
1586                                         WARN("BAD_SIGN_OFF",
1587                                              "email address '$email' might be better as '$suggested_email$comment'\n" . $herecurr);
1588                                 }
1589                         }
1590                 }
1591
1592 # Check for wrappage within a valid hunk of the file
1593                 if ($realcnt != 0 && $line !~ m{^(?:\+|-| |\\ No newline|$)}) {
1594                         ERROR("CORRUPTED_PATCH",
1595                               "patch seems to be corrupt (line wrapped?)\n" .
1596                                 $herecurr) if (!$emitted_corrupt++);
1597                 }
1598
1599 # Check for absolute kernel paths.
1600                 if ($tree) {
1601                         while ($line =~ m{(?:^|\s)(/\S*)}g) {
1602                                 my $file = $1;
1603
1604                                 if ($file =~ m{^(.*?)(?::\d+)+:?$} &&
1605                                     check_absolute_file($1, $herecurr)) {
1606                                         #
1607                                 } else {
1608                                         check_absolute_file($file, $herecurr);
1609                                 }
1610                         }
1611                 }
1612
1613 # UTF-8 regex found at http://www.w3.org/International/questions/qa-forms-utf-8.en.php
1614                 if (($realfile =~ /^$/ || $line =~ /^\+/) &&
1615                     $rawline !~ m/^$UTF8*$/) {
1616                         my ($utf8_prefix) = ($rawline =~ /^($UTF8*)/);
1617
1618                         my $blank = copy_spacing($rawline);
1619                         my $ptr = substr($blank, 0, length($utf8_prefix)) . "^";
1620                         my $hereptr = "$hereline$ptr\n";
1621
1622                         CHK("INVALID_UTF8",
1623                             "Invalid UTF-8, patch and commit message should be encoded in UTF-8\n" . $hereptr);
1624                 }
1625
1626 # Check if it's the start of a commit log
1627 # (not a header line and we haven't seen the patch filename)
1628                 if ($in_header_lines && $realfile =~ /^$/ &&
1629                     $rawline !~ /^(commit\b|from\b|\w+:).+$/i) {
1630                         $in_header_lines = 0;
1631                         $in_commit_log = 1;
1632                 }
1633
1634 # Still not yet in a patch, check for any UTF-8
1635                 if ($in_commit_log && $realfile =~ /^$/ &&
1636                     $rawline =~ /$NON_ASCII_UTF8/) {
1637                         CHK("UTF8_BEFORE_PATCH",
1638                             "8-bit UTF-8 used in possible commit log\n" . $herecurr);
1639                 }
1640
1641 # ignore non-hunk lines and lines being removed
1642                 next if (!$hunk_line || $line =~ /^-/);
1643
1644 #trailing whitespace
1645                 if ($line =~ /^\+.*\015/) {
1646                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1647                         ERROR("DOS_LINE_ENDINGS",
1648                               "DOS line endings\n" . $herevet);
1649
1650                 } elsif ($rawline =~ /^\+.*\S\s+$/ || $rawline =~ /^\+\s+$/) {
1651                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1652                         ERROR("TRAILING_WHITESPACE",
1653                               "trailing whitespace\n" . $herevet);
1654                         $rpt_cleaners = 1;
1655                 }
1656
1657 # check for Kconfig help text having a real description
1658 # Only applies when adding the entry originally, after that we do not have
1659 # sufficient context to determine whether it is indeed long enough.
1660                 if ($realfile =~ /Kconfig/ &&
1661                     $line =~ /\+\s*(?:---)?help(?:---)?$/) {
1662                         my $length = 0;
1663                         my $cnt = $realcnt;
1664                         my $ln = $linenr + 1;
1665                         my $f;
1666                         my $is_end = 0;
1667                         while ($cnt > 0 && defined $lines[$ln - 1]) {
1668                                 $f = $lines[$ln - 1];
1669                                 $cnt-- if ($lines[$ln - 1] !~ /^-/);
1670                                 $is_end = $lines[$ln - 1] =~ /^\+/;
1671                                 $ln++;
1672
1673                                 next if ($f =~ /^-/);
1674                                 $f =~ s/^.//;
1675                                 $f =~ s/#.*//;
1676                                 $f =~ s/^\s+//;
1677                                 next if ($f =~ /^$/);
1678                                 if ($f =~ /^\s*config\s/) {
1679                                         $is_end = 1;
1680                                         last;
1681                                 }
1682                                 $length++;
1683                         }
1684                         WARN("CONFIG_DESCRIPTION",
1685                              "please write a paragraph that describes the config symbol fully\n" . $herecurr) if ($is_end && $length < 4);
1686                         #print "is_end<$is_end> length<$length>\n";
1687                 }
1688
1689                 if (($realfile =~ /Makefile.*/ || $realfile =~ /Kbuild.*/) &&
1690                     ($line =~ /\+(EXTRA_[A-Z]+FLAGS).*/)) {
1691                         my $flag = $1;
1692                         my $replacement = {
1693                                 'EXTRA_AFLAGS' =>   'asflags-y',
1694                                 'EXTRA_CFLAGS' =>   'ccflags-y',
1695                                 'EXTRA_CPPFLAGS' => 'cppflags-y',
1696                                 'EXTRA_LDFLAGS' =>  'ldflags-y',
1697                         };
1698
1699                         WARN("DEPRECATED_VARIABLE",
1700                              "Use of $flag is deprecated, please use \`$replacement->{$flag} instead.\n" . $herecurr) if ($replacement->{$flag});
1701                 }
1702
1703 # check we are in a valid source file if not then ignore this hunk
1704                 next if ($realfile !~ /\.(h|c|s|S|pl|sh)$/);
1705
1706 #80 column limit
1707                 if ($line =~ /^\+/ && $prevrawline !~ /\/\*\*/ &&
1708                     $rawline !~ /^.\s*\*\s*\@$Ident\s/ &&
1709                     !($line =~ /^\+\s*$logFunctions\s*\(\s*(?:(KERN_\S+\s*|[^"]*))?"[X\t]*"\s*(?:|,|\)\s*;)\s*$/ ||
1710                     $line =~ /^\+\s*"[^"]*"\s*(?:\s*|,|\)\s*;)\s*$/) &&
1711                     $length > 80)
1712                 {
1713                         WARN("LONG_LINE",
1714                              "line over 80 characters\n" . $herecurr);
1715                 }
1716
1717 # check for spaces before a quoted newline
1718                 if ($rawline =~ /^.*\".*\s\\n/) {
1719                         WARN("QUOTED_WHITESPACE_BEFORE_NEWLINE",
1720                              "unnecessary whitespace before a quoted newline\n" . $herecurr);
1721                 }
1722
1723 # check for adding lines without a newline.
1724                 if ($line =~ /^\+/ && defined $lines[$linenr] && $lines[$linenr] =~ /^\\ No newline at end of file/) {
1725                         WARN("MISSING_EOF_NEWLINE",
1726                              "adding a line without newline at end of file\n" . $herecurr);
1727                 }
1728
1729 # Blackfin: use hi/lo macros
1730                 if ($realfile =~ m@arch/blackfin/.*\.S$@) {
1731                         if ($line =~ /\.[lL][[:space:]]*=.*&[[:space:]]*0x[fF][fF][fF][fF]/) {
1732                                 my $herevet = "$here\n" . cat_vet($line) . "\n";
1733                                 ERROR("LO_MACRO",
1734                                       "use the LO() macro, not (... & 0xFFFF)\n" . $herevet);
1735                         }
1736                         if ($line =~ /\.[hH][[:space:]]*=.*>>[[:space:]]*16/) {
1737                                 my $herevet = "$here\n" . cat_vet($line) . "\n";
1738                                 ERROR("HI_MACRO",
1739                                       "use the HI() macro, not (... >> 16)\n" . $herevet);
1740                         }
1741                 }
1742
1743 # check we are in a valid source file C or perl if not then ignore this hunk
1744                 next if ($realfile !~ /\.(h|c|pl)$/);
1745
1746 # at the beginning of a line any tabs must come first and anything
1747 # more than 8 must use tabs.
1748                 if ($rawline =~ /^\+\s* \t\s*\S/ ||
1749                     $rawline =~ /^\+\s*        \s*/) {
1750                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1751                         ERROR("CODE_INDENT",
1752                               "code indent should use tabs where possible\n" . $herevet);
1753                         $rpt_cleaners = 1;
1754                 }
1755
1756 # check for space before tabs.
1757                 if ($rawline =~ /^\+/ && $rawline =~ / \t/) {
1758                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1759                         WARN("SPACE_BEFORE_TAB",
1760                              "please, no space before tabs\n" . $herevet);
1761                 }
1762
1763 # check for spaces at the beginning of a line.
1764 # Exceptions:
1765 #  1) within comments
1766 #  2) indented preprocessor commands
1767 #  3) hanging labels
1768                 if ($rawline =~ /^\+ / && $line !~ /\+ *(?:$;|#|$Ident:)/)  {
1769                         my $herevet = "$here\n" . cat_vet($rawline) . "\n";
1770                         WARN("LEADING_SPACE",
1771                              "please, no spaces at the start of a line\n" . $herevet);
1772                 }
1773
1774 # check we are in a valid C source file if not then ignore this hunk
1775                 next if ($realfile !~ /\.(h|c)$/);
1776
1777 # check for RCS/CVS revision markers
1778                 if ($rawline =~ /^\+.*\$(Revision|Log|Id)(?:\$|)/) {
1779                         WARN("CVS_KEYWORD",
1780                              "CVS style keyword markers, these will _not_ be updated\n". $herecurr);
1781                 }
1782
1783 # Blackfin: don't use __builtin_bfin_[cs]sync
1784                 if ($line =~ /__builtin_bfin_csync/) {
1785                         my $herevet = "$here\n" . cat_vet($line) . "\n";
1786                         ERROR("CSYNC",
1787                               "use the CSYNC() macro in asm/blackfin.h\n" . $herevet);
1788                 }
1789                 if ($line =~ /__builtin_bfin_ssync/) {
1790                         my $herevet = "$here\n" . cat_vet($line) . "\n";
1791                         ERROR("SSYNC",
1792                               "use the SSYNC() macro in asm/blackfin.h\n" . $herevet);
1793                 }
1794
1795 # Check for potential 'bare' types
1796                 my ($stat, $cond, $line_nr_next, $remain_next, $off_next,
1797                     $realline_next);
1798                 if ($realcnt && $line =~ /.\s*\S/) {
1799                         ($stat, $cond, $line_nr_next, $remain_next, $off_next) =
1800                                 ctx_statement_block($linenr, $realcnt, 0);
1801                         $stat =~ s/\n./\n /g;
1802                         $cond =~ s/\n./\n /g;
1803
1804                         # Find the real next line.
1805                         $realline_next = $line_nr_next;
1806                         if (defined $realline_next &&
1807                             (!defined $lines[$realline_next - 1] ||
1808                              substr($lines[$realline_next - 1], $off_next) =~ /^\s*$/)) {
1809                                 $realline_next++;
1810                         }
1811
1812                         my $s = $stat;
1813                         $s =~ s/{.*$//s;
1814
1815                         # Ignore goto labels.
1816                         if ($s =~ /$Ident:\*$/s) {
1817
1818                         # Ignore functions being called
1819                         } elsif ($s =~ /^.\s*$Ident\s*\(/s) {
1820
1821                         } elsif ($s =~ /^.\s*else\b/s) {
1822
1823                         # declarations always start with types
1824                         } elsif ($prev_values eq 'E' && $s =~ /^.\s*(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?((?:\s*$Ident)+?)\b(?:\s+$Sparse)?\s*\**\s*(?:$Ident|\(\*[^\)]*\))(?:\s*$Modifier)?\s*(?:;|=|,|\()/s) {
1825                                 my $type = $1;
1826                                 $type =~ s/\s+/ /g;
1827                                 possible($type, "A:" . $s);
1828
1829                         # definitions in global scope can only start with types
1830                         } elsif ($s =~ /^.(?:$Storage\s+)?(?:$Inline\s+)?(?:const\s+)?($Ident)\b\s*(?!:)/s) {
1831                                 possible($1, "B:" . $s);
1832                         }
1833
1834                         # any (foo ... *) is a pointer cast, and foo is a type
1835                         while ($s =~ /\(($Ident)(?:\s+$Sparse)*[\s\*]+\s*\)/sg) {
1836                                 possible($1, "C:" . $s);
1837                         }
1838
1839                         # Check for any sort of function declaration.
1840                         # int foo(something bar, other baz);
1841                         # void (*store_gdt)(x86_descr_ptr *);
1842                         if ($prev_values eq 'E' && $s =~ /^(.(?:typedef\s*)?(?:(?:$Storage|$Inline)\s*)*\s*$Type\s*(?:\b$Ident|\(\*\s*$Ident\))\s*)\(/s) {
1843                                 my ($name_len) = length($1);
1844
1845                                 my $ctx = $s;
1846                                 substr($ctx, 0, $name_len + 1, '');
1847                                 $ctx =~ s/\)[^\)]*$//;
1848
1849                                 for my $arg (split(/\s*,\s*/, $ctx)) {
1850                                         if ($arg =~ /^(?:const\s+)?($Ident)(?:\s+$Sparse)*\s*\**\s*(:?\b$Ident)?$/s || $arg =~ /^($Ident)$/s) {
1851
1852                                                 possible($1, "D:" . $s);
1853                                         }
1854                                 }
1855                         }
1856
1857                 }
1858
1859 #
1860 # Checks which may be anchored in the context.
1861 #
1862
1863 # Check for switch () and associated case and default
1864 # statements should be at the same indent.
1865                 if ($line=~/\bswitch\s*\(.*\)/) {
1866                         my $err = '';
1867                         my $sep = '';
1868                         my @ctx = ctx_block_outer($linenr, $realcnt);
1869                         shift(@ctx);
1870                         for my $ctx (@ctx) {
1871                                 my ($clen, $cindent) = line_stats($ctx);
1872                                 if ($ctx =~ /^\+\s*(case\s+|default:)/ &&
1873                                                         $indent != $cindent) {
1874                                         $err .= "$sep$ctx\n";
1875                                         $sep = '';
1876                                 } else {
1877                                         $sep = "[...]\n";
1878                                 }
1879                         }
1880                         if ($err ne '') {
1881                                 ERROR("SWITCH_CASE_INDENT_LEVEL",
1882                                       "switch and case should be at the same indent\n$hereline$err");
1883                         }
1884                 }
1885
1886 # if/while/etc brace do not go on next line, unless defining a do while loop,
1887 # or if that brace on the next line is for something else
1888                 if ($line =~ /(.*)\b((?:if|while|for|switch)\s*\(|do\b|else\b)/ && $line !~ /^.\s*\#/) {
1889                         my $pre_ctx = "$1$2";
1890
1891                         my ($level, @ctx) = ctx_statement_level($linenr, $realcnt, 0);
1892                         my $ctx_cnt = $realcnt - $#ctx - 1;
1893                         my $ctx = join("\n", @ctx);
1894
1895                         my $ctx_ln = $linenr;
1896                         my $ctx_skip = $realcnt;
1897
1898                         while ($ctx_skip > $ctx_cnt || ($ctx_skip == $ctx_cnt &&
1899                                         defined $lines[$ctx_ln - 1] &&
1900                                         $lines[$ctx_ln - 1] =~ /^-/)) {
1901                                 ##print "SKIP<$ctx_skip> CNT<$ctx_cnt>\n";
1902                                 $ctx_skip-- if (!defined $lines[$ctx_ln - 1] || $lines[$ctx_ln - 1] !~ /^-/);
1903                                 $ctx_ln++;
1904                         }
1905
1906                         #print "realcnt<$realcnt> ctx_cnt<$ctx_cnt>\n";
1907                         #print "pre<$pre_ctx>\nline<$line>\nctx<$ctx>\nnext<$lines[$ctx_ln - 1]>\n";
1908
1909                         if ($ctx !~ /{\s*/ && defined($lines[$ctx_ln -1]) && $lines[$ctx_ln - 1] =~ /^\+\s*{/) {
1910                                 ERROR("OPEN_BRACE",
1911                                       "that open brace { should be on the previous line\n" .
1912                                         "$here\n$ctx\n$rawlines[$ctx_ln - 1]\n");
1913                         }
1914                         if ($level == 0 && $pre_ctx !~ /}\s*while\s*\($/ &&
1915                             $ctx =~ /\)\s*\;\s*$/ &&
1916                             defined $lines[$ctx_ln - 1])
1917                         {
1918                                 my ($nlength, $nindent) = line_stats($lines[$ctx_ln - 1]);
1919                                 if ($nindent > $indent) {
1920                                         WARN("TRAILING_SEMICOLON",
1921                                              "trailing semicolon indicates no statements, indent implies otherwise\n" .
1922                                                 "$here\n$ctx\n$rawlines[$ctx_ln - 1]\n");
1923                                 }
1924                         }
1925                 }
1926
1927 # Check relative indent for conditionals and blocks.
1928                 if ($line =~ /\b(?:(?:if|while|for)\s*\(|do\b)/ && $line !~ /^.\s*#/ && $line !~ /\}\s*while\s*/) {
1929                         my ($s, $c) = ($stat, $cond);
1930
1931                         substr($s, 0, length($c), '');
1932
1933                         # Make sure we remove the line prefixes as we have
1934                         # none on the first line, and are going to readd them
1935                         # where necessary.
1936                         $s =~ s/\n./\n/gs;
1937
1938                         # Find out how long the conditional actually is.
1939                         my @newlines = ($c =~ /\n/gs);
1940                         my $cond_lines = 1 + $#newlines;
1941
1942                         # We want to check the first line inside the block
1943                         # starting at the end of the conditional, so remove:
1944                         #  1) any blank line termination
1945                         #  2) any opening brace { on end of the line
1946                         #  3) any do (...) {
1947                         my $continuation = 0;
1948                         my $check = 0;
1949                         $s =~ s/^.*\bdo\b//;
1950                         $s =~ s/^\s*{//;
1951                         if ($s =~ s/^\s*\\//) {
1952                                 $continuation = 1;
1953                         }
1954                         if ($s =~ s/^\s*?\n//) {
1955                                 $check = 1;
1956                                 $cond_lines++;
1957                         }
1958
1959                         # Also ignore a loop construct at the end of a
1960                         # preprocessor statement.
1961                         if (($prevline =~ /^.\s*#\s*define\s/ ||
1962                             $prevline =~ /\\\s*$/) && $continuation == 0) {
1963                                 $check = 0;
1964                         }
1965
1966                         my $cond_ptr = -1;
1967                         $continuation = 0;
1968                         while ($cond_ptr != $cond_lines) {
1969                                 $cond_ptr = $cond_lines;
1970
1971                                 # If we see an #else/#elif then the code
1972                                 # is not linear.
1973                                 if ($s =~ /^\s*\#\s*(?:else|elif)/) {
1974                                         $check = 0;
1975                                 }
1976
1977                                 # Ignore:
1978                                 #  1) blank lines, they should be at 0,
1979                                 #  2) preprocessor lines, and
1980                                 #  3) labels.
1981                                 if ($continuation ||
1982                                     $s =~ /^\s*?\n/ ||
1983                                     $s =~ /^\s*#\s*?/ ||
1984                                     $s =~ /^\s*$Ident\s*:/) {
1985                                         $continuation = ($s =~ /^.*?\\\n/) ? 1 : 0;
1986                                         if ($s =~ s/^.*?\n//) {
1987                                                 $cond_lines++;
1988                                         }
1989                                 }
1990                         }
1991
1992                         my (undef, $sindent) = line_stats("+" . $s);
1993                         my $stat_real = raw_line($linenr, $cond_lines);
1994
1995                         # Check if either of these lines are modified, else
1996                         # this is not this patch's fault.
1997                         if (!defined($stat_real) ||
1998                             $stat !~ /^\+/ && $stat_real !~ /^\+/) {
1999                                 $check = 0;
2000                         }
2001                         if (defined($stat_real) && $cond_lines > 1) {
2002                                 $stat_real = "[...]\n$stat_real";
2003                         }
2004
2005                         #print "line<$line> prevline<$prevline> indent<$indent> sindent<$sindent> check<$check> continuation<$continuation> s<$s> cond_lines<$cond_lines> stat_real<$stat_real> stat<$stat>\n";
2006
2007                         if ($check && (($sindent % 8) != 0 ||
2008                             ($sindent <= $indent && $s ne ''))) {
2009                                 WARN("SUSPECT_CODE_INDENT",
2010                                      "suspect code indent for conditional statements ($indent, $sindent)\n" . $herecurr . "$stat_real\n");
2011                         }
2012                 }
2013
2014                 # Track the 'values' across context and added lines.
2015                 my $opline = $line; $opline =~ s/^./ /;
2016                 my ($curr_values, $curr_vars) =
2017                                 annotate_values($opline . "\n", $prev_values);
2018                 $curr_values = $prev_values . $curr_values;
2019                 if ($dbg_values) {
2020                         my $outline = $opline; $outline =~ s/\t/ /g;
2021                         print "$linenr > .$outline\n";
2022                         print "$linenr > $curr_values\n";
2023                         print "$linenr >  $curr_vars\n";
2024                 }
2025                 $prev_values = substr($curr_values, -1);
2026
2027 #ignore lines not being added
2028                 if ($line=~/^[^\+]/) {next;}
2029
2030 # TEST: allow direct testing of the type matcher.
2031                 if ($dbg_type) {
2032                         if ($line =~ /^.\s*$Declare\s*$/) {
2033                                 ERROR("TEST_TYPE",
2034                                       "TEST: is type\n" . $herecurr);
2035                         } elsif ($dbg_type > 1 && $line =~ /^.+($Declare)/) {
2036                                 ERROR("TEST_NOT_TYPE",
2037                                       "TEST: is not type ($1 is)\n". $herecurr);
2038                         }
2039                         next;
2040                 }
2041 # TEST: allow direct testing of the attribute matcher.
2042                 if ($dbg_attr) {
2043                         if ($line =~ /^.\s*$Modifier\s*$/) {
2044                                 ERROR("TEST_ATTR",
2045                                       "TEST: is attr\n" . $herecurr);
2046                         } elsif ($dbg_attr > 1 && $line =~ /^.+($Modifier)/) {
2047                                 ERROR("TEST_NOT_ATTR",
2048                                       "TEST: is not attr ($1 is)\n". $herecurr);
2049                         }
2050                         next;
2051                 }
2052
2053 # check for initialisation to aggregates open brace on the next line
2054                 if ($line =~ /^.\s*{/ &&
2055                     $prevline =~ /(?:^|[^=])=\s*$/) {
2056                         ERROR("OPEN_BRACE",
2057                               "that open brace { should be on the previous line\n" . $hereprev);
2058                 }
2059
2060 #
2061 # Checks which are anchored on the added line.
2062 #
2063
2064 # check for malformed paths in #include statements (uses RAW line)
2065                 if ($rawline =~ m{^.\s*\#\s*include\s+[<"](.*)[">]}) {
2066                         my $path = $1;
2067                         if ($path =~ m{//}) {
2068                                 ERROR("MALFORMED_INCLUDE",
2069                                       "malformed #include filename\n" .
2070                                         $herecurr);
2071                         }
2072                 }
2073
2074 # no C99 // comments
2075                 if ($line =~ m{//}) {
2076                         ERROR("C99_COMMENTS",
2077                               "do not use C99 // comments\n" . $herecurr);
2078                 }
2079                 # Remove C99 comments.
2080                 $line =~ s@//.*@@;
2081                 $opline =~ s@//.*@@;
2082
2083 # EXPORT_SYMBOL should immediately follow the thing it is exporting, consider
2084 # the whole statement.
2085 #print "APW <$lines[$realline_next - 1]>\n";
2086                 if (defined $realline_next &&
2087                     exists $lines[$realline_next - 1] &&
2088                     !defined $suppress_export{$realline_next} &&
2089                     ($lines[$realline_next - 1] =~ /EXPORT_SYMBOL.*\((.*)\)/ ||
2090                      $lines[$realline_next - 1] =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
2091                         # Handle definitions which produce identifiers with
2092                         # a prefix:
2093                         #   XXX(foo);
2094                         #   EXPORT_SYMBOL(something_foo);
2095                         my $name = $1;
2096                         if ($stat =~ /^.([A-Z_]+)\s*\(\s*($Ident)/ &&
2097                             $name =~ /^${Ident}_$2/) {
2098 #print "FOO C name<$name>\n";
2099                                 $suppress_export{$realline_next} = 1;
2100
2101                         } elsif ($stat !~ /(?:
2102                                 \n.}\s*$|
2103                                 ^.DEFINE_$Ident\(\Q$name\E\)|
2104                                 ^.DECLARE_$Ident\(\Q$name\E\)|
2105                                 ^.LIST_HEAD\(\Q$name\E\)|
2106                                 ^.(?:$Storage\s+)?$Type\s*\(\s*\*\s*\Q$name\E\s*\)\s*\(|
2107                                 \b\Q$name\E(?:\s+$Attribute)*\s*(?:;|=|\[|\()
2108                             )/x) {
2109 #print "FOO A<$lines[$realline_next - 1]> stat<$stat> name<$name>\n";
2110                                 $suppress_export{$realline_next} = 2;
2111                         } else {
2112                                 $suppress_export{$realline_next} = 1;
2113                         }
2114                 }
2115                 if (!defined $suppress_export{$linenr} &&
2116                     $prevline =~ /^.\s*$/ &&
2117                     ($line =~ /EXPORT_SYMBOL.*\((.*)\)/ ||
2118                      $line =~ /EXPORT_UNUSED_SYMBOL.*\((.*)\)/)) {
2119 #print "FOO B <$lines[$linenr - 1]>\n";
2120                         $suppress_export{$linenr} = 2;
2121                 }
2122                 if (defined $suppress_export{$linenr} &&
2123                     $suppress_export{$linenr} == 2) {
2124                         WARN("EXPORT_SYMBOL",
2125                              "EXPORT_SYMBOL(foo); should immediately follow its function/variable\n" . $herecurr);
2126                 }
2127
2128 # check for global initialisers.
2129                 if ($line =~ /^.$Type\s*$Ident\s*(?:\s+$Modifier)*\s*=\s*(0|NULL|false)\s*;/) {
2130                         ERROR("GLOBAL_INITIALISERS",
2131                               "do not initialise globals to 0 or NULL\n" .
2132                                 $herecurr);
2133                 }
2134 # check for static initialisers.
2135                 if ($line =~ /\bstatic\s.*=\s*(0|NULL|false)\s*;/) {
2136                         ERROR("INITIALISED_STATIC",
2137                               "do not initialise statics to 0 or NULL\n" .
2138                                 $herecurr);
2139                 }
2140
2141 # check for static const char * arrays.
2142                 if ($line =~ /\bstatic\s+const\s+char\s*\*\s*(\w+)\s*\[\s*\]\s*=\s*/) {
2143                         WARN("STATIC_CONST_CHAR_ARRAY",
2144                              "static const char * array should probably be static const char * const\n" .
2145                                 $herecurr);
2146                }
2147
2148 # check for static char foo[] = "bar" declarations.
2149                 if ($line =~ /\bstatic\s+char\s+(\w+)\s*\[\s*\]\s*=\s*"/) {
2150                         WARN("STATIC_CONST_CHAR_ARRAY",
2151                              "static char array declaration should probably be static const char\n" .
2152                                 $herecurr);
2153                }
2154
2155 # check for declarations of struct pci_device_id
2156                 if ($line =~ /\bstruct\s+pci_device_id\s+\w+\s*\[\s*\]\s*\=\s*\{/) {
2157                         WARN("DEFINE_PCI_DEVICE_TABLE",
2158                              "Use DEFINE_PCI_DEVICE_TABLE for struct pci_device_id\n" . $herecurr);
2159                 }
2160
2161 # check for new typedefs, only function parameters and sparse annotations
2162 # make sense.
2163                 if ($line =~ /\btypedef\s/ &&
2164                     $line !~ /\btypedef\s+$Type\s*\(\s*\*?$Ident\s*\)\s*\(/ &&
2165                     $line !~ /\btypedef\s+$Type\s+$Ident\s*\(/ &&
2166                     $line !~ /\b$typeTypedefs\b/ &&
2167                     $line !~ /\b__bitwise(?:__|)\b/) {
2168                         WARN("NEW_TYPEDEFS",
2169                              "do not add new typedefs\n" . $herecurr);
2170                 }
2171
2172 # * goes on variable not on type
2173                 # (char*[ const])
2174                 if ($line =~ m{\($NonptrType(\s*(?:$Modifier\b\s*|\*\s*)+)\)}) {
2175                         my ($from, $to) = ($1, $1);
2176
2177                         # Should start with a space.
2178                         $to =~ s/^(\S)/ $1/;
2179                         # Should not end with a space.
2180                         $to =~ s/\s+$//;
2181                         # '*'s should not have spaces between.
2182                         while ($to =~ s/\*\s+\*/\*\*/) {
2183                         }
2184
2185                         #print "from<$from> to<$to>\n";
2186                         if ($from ne $to) {
2187                                 ERROR("POINTER_LOCATION",
2188                                       "\"(foo$from)\" should be \"(foo$to)\"\n" .  $herecurr);
2189                         }
2190                 } elsif ($line =~ m{\b$NonptrType(\s*(?:$Modifier\b\s*|\*\s*)+)($Ident)}) {
2191                         my ($from, $to, $ident) = ($1, $1, $2);
2192
2193                         # Should start with a space.
2194                         $to =~ s/^(\S)/ $1/;
2195                         # Should not end with a space.
2196                         $to =~ s/\s+$//;
2197                         # '*'s should not have spaces between.
2198                         while ($to =~ s/\*\s+\*/\*\*/) {
2199                         }
2200                         # Modifiers should have spaces.
2201                         $to =~ s/(\b$Modifier$)/$1 /;
2202
2203                         #print "from<$from> to<$to> ident<$ident>\n";
2204                         if ($from ne $to && $ident !~ /^$Modifier$/) {
2205                                 ERROR("POINTER_LOCATION",
2206                                       "\"foo${from}bar\" should be \"foo${to}bar\"\n" .  $herecurr);
2207                         }
2208                 }
2209
2210 # # no BUG() or BUG_ON()
2211 #               if ($line =~ /\b(BUG|BUG_ON)\b/) {
2212 #                       print "Try to use WARN_ON & Recovery code rather than BUG() or BUG_ON()\n";
2213 #                       print "$herecurr";
2214 #                       $clean = 0;
2215 #               }
2216
2217                 if ($line =~ /\bLINUX_VERSION_CODE\b/) {
2218                         WARN("LINUX_VERSION_CODE",
2219                              "LINUX_VERSION_CODE should be avoided, code should be for the version to which it is merged\n" . $herecurr);
2220                 }
2221
2222 # check for uses of printk_ratelimit
2223                 if ($line =~ /\bprintk_ratelimit\s*\(/) {
2224                         WARN("PRINTK_RATELIMITED",
2225 "Prefer printk_ratelimited or pr_<level>_ratelimited to printk_ratelimit\n" . $herecurr);
2226                 }
2227
2228 # printk should use KERN_* levels.  Note that follow on printk's on the
2229 # same line do not need a level, so we use the current block context
2230 # to try and find and validate the current printk.  In summary the current
2231 # printk includes all preceding printk's which have no newline on the end.
2232 # we assume the first bad printk is the one to report.
2233                 if ($line =~ /\bprintk\((?!KERN_)\s*"/) {
2234                         my $ok = 0;
2235                         for (my $ln = $linenr - 1; $ln >= $first_line; $ln--) {
2236                                 #print "CHECK<$lines[$ln - 1]\n";
2237                                 # we have a preceding printk if it ends
2238                                 # with "\n" ignore it, else it is to blame
2239                                 if ($lines[$ln - 1] =~ m{\bprintk\(}) {
2240                                         if ($rawlines[$ln - 1] !~ m{\\n"}) {
2241                                                 $ok = 1;
2242                                         }
2243                                         last;
2244                                 }
2245                         }
2246                         if ($ok == 0) {
2247                                 WARN("PRINTK_WITHOUT_KERN_LEVEL",
2248                                      "printk() should include KERN_ facility level\n" . $herecurr);
2249                         }
2250                 }
2251
2252 # function brace can't be on same line, except for #defines of do while,
2253 # or if closed on same line
2254                 if (($line=~/$Type\s*$Ident\(.*\).*\s{/) and
2255                     !($line=~/\#\s*define.*do\s{/) and !($line=~/}/)) {
2256                         ERROR("OPEN_BRACE",
2257                               "open brace '{' following function declarations go on the next line\n" . $herecurr);
2258                 }
2259
2260 # open braces for enum, union and struct go on the same line.
2261                 if ($line =~ /^.\s*{/ &&
2262                     $prevline =~ /^.\s*(?:typedef\s+)?(enum|union|struct)(?:\s+$Ident)?\s*$/) {
2263                         ERROR("OPEN_BRACE",
2264                               "open brace '{' following $1 go on the same line\n" . $hereprev);
2265                 }
2266
2267 # missing space after union, struct or enum definition
2268                 if ($line =~ /^.\s*(?:typedef\s+)?(enum|union|struct)(?:\s+$Ident)?(?:\s+$Ident)?[=\{]/) {
2269                     WARN("SPACING",
2270                          "missing space after $1 definition\n" . $herecurr);
2271                 }
2272
2273 # check for spacing round square brackets; allowed:
2274 #  1. with a type on the left -- int [] a;
2275 #  2. at the beginning of a line for slice initialisers -- [0...10] = 5,
2276 #  3. inside a curly brace -- = { [0...10] = 5 }
2277                 while ($line =~ /(.*?\s)\[/g) {
2278                         my ($where, $prefix) = ($-[1], $1);
2279                         if ($prefix !~ /$Type\s+$/ &&
2280                             ($where != 0 || $prefix !~ /^.\s+$/) &&
2281                             $prefix !~ /{\s+$/) {
2282                                 ERROR("BRACKET_SPACE",
2283                                       "space prohibited before open square bracket '['\n" . $herecurr);
2284                         }
2285                 }
2286
2287 # check for spaces between functions and their parentheses.
2288                 while ($line =~ /($Ident)\s+\(/g) {
2289                         my $name = $1;
2290                         my $ctx_before = substr($line, 0, $-[1]);
2291                         my $ctx = "$ctx_before$name";
2292
2293                         # Ignore those directives where spaces _are_ permitted.
2294                         if ($name =~ /^(?:
2295                                 if|for|while|switch|return|case|
2296                                 volatile|__volatile__|
2297                                 __attribute__|format|__extension__|
2298                                 asm|__asm__)$/x)
2299                         {
2300
2301                         # cpp #define statements have non-optional spaces, ie
2302                         # if there is a space between the name and the open
2303                         # parenthesis it is simply not a parameter group.
2304                         } elsif ($ctx_before =~ /^.\s*\#\s*define\s*$/) {
2305
2306                         # cpp #elif statement condition may start with a (
2307                         } elsif ($ctx =~ /^.\s*\#\s*elif\s*$/) {
2308
2309                         # If this whole things ends with a type its most
2310                         # likely a typedef for a function.
2311                         } elsif ($ctx =~ /$Type$/) {
2312
2313                         } else {
2314                                 WARN("SPACING",
2315                                      "space prohibited between function name and open parenthesis '('\n" . $herecurr);
2316                         }
2317                 }
2318 # Check operator spacing.
2319                 if (!($line=~/\#\s*include/)) {
2320                         my $ops = qr{
2321                                 <<=|>>=|<=|>=|==|!=|
2322                                 \+=|-=|\*=|\/=|%=|\^=|\|=|&=|
2323                                 =>|->|<<|>>|<|>|=|!|~|
2324                                 &&|\|\||,|\^|\+\+|--|&|\||\+|-|\*|\/|%|
2325                                 \?|:
2326                         }x;
2327                         my @elements = split(/($ops|;)/, $opline);
2328                         my $off = 0;
2329
2330                         my $blank = copy_spacing($opline);
2331
2332                         for (my $n = 0; $n < $#elements; $n += 2) {
2333                                 $off += length($elements[$n]);
2334
2335                                 # Pick up the preceding and succeeding characters.
2336                                 my $ca = substr($opline, 0, $off);
2337                                 my $cc = '';
2338                                 if (length($opline) >= ($off + length($elements[$n + 1]))) {
2339                                         $cc = substr($opline, $off + length($elements[$n + 1]));
2340                                 }
2341                                 my $cb = "$ca$;$cc";
2342
2343                                 my $a = '';
2344                                 $a = 'V' if ($elements[$n] ne '');
2345                                 $a = 'W' if ($elements[$n] =~ /\s$/);
2346                                 $a = 'C' if ($elements[$n] =~ /$;$/);
2347                                 $a = 'B' if ($elements[$n] =~ /(\[|\()$/);
2348                                 $a = 'O' if ($elements[$n] eq '');
2349                                 $a = 'E' if ($ca =~ /^\s*$/);
2350
2351                                 my $op = $elements[$n + 1];
2352
2353                                 my $c = '';
2354                                 if (defined $elements[$n + 2]) {
2355                                         $c = 'V' if ($elements[$n + 2] ne '');
2356                                         $c = 'W' if ($elements[$n + 2] =~ /^\s/);
2357                                         $c = 'C' if ($elements[$n + 2] =~ /^$;/);
2358                                         $c = 'B' if ($elements[$n + 2] =~ /^(\)|\]|;)/);
2359                                         $c = 'O' if ($elements[$n + 2] eq '');
2360                                         $c = 'E' if ($elements[$n + 2] =~ /^\s*\\$/);
2361                                 } else {
2362                                         $c = 'E';
2363                                 }
2364
2365                                 my $ctx = "${a}x${c}";
2366
2367                                 my $at = "(ctx:$ctx)";
2368
2369                                 my $ptr = substr($blank, 0, $off) . "^";
2370                                 my $hereptr = "$hereline$ptr\n";
2371
2372                                 # Pull out the value of this operator.
2373                                 my $op_type = substr($curr_values, $off + 1, 1);
2374
2375                                 # Get the full operator variant.
2376                                 my $opv = $op . substr($curr_vars, $off, 1);
2377
2378                                 # Ignore operators passed as parameters.
2379                                 if ($op_type ne 'V' &&
2380                                     $ca =~ /\s$/ && $cc =~ /^\s*,/) {
2381
2382 #                               # Ignore comments
2383 #                               } elsif ($op =~ /^$;+$/) {
2384
2385                                 # ; should have either the end of line or a space or \ after it
2386                                 } elsif ($op eq ';') {
2387                                         if ($ctx !~ /.x[WEBC]/ &&
2388                                             $cc !~ /^\\/ && $cc !~ /^;/) {
2389                                                 ERROR("SPACING",
2390                                                       "space required after that '$op' $at\n" . $hereptr);
2391                                         }
2392
2393                                 # // is a comment
2394                                 } elsif ($op eq '//') {
2395
2396                                 # No spaces for:
2397                                 #   ->
2398                                 #   :   when part of a bitfield
2399                                 } elsif ($op eq '->' || $opv eq ':B') {
2400                                         if ($ctx =~ /Wx.|.xW/) {
2401                                                 ERROR("SPACING",
2402                                                       "spaces prohibited around that '$op' $at\n" . $hereptr);
2403                                         }
2404
2405                                 # , must have a space on the right.
2406                                 } elsif ($op eq ',') {
2407                                         if ($ctx !~ /.x[WEC]/ && $cc !~ /^}/) {
2408                                                 ERROR("SPACING",
2409                                                       "space required after that '$op' $at\n" . $hereptr);
2410                                         }
2411
2412                                 # '*' as part of a type definition -- reported already.
2413                                 } elsif ($opv eq '*_') {
2414                                         #warn "'*' is part of type\n";
2415
2416                                 # unary operators should have a space before and
2417                                 # none after.  May be left adjacent to another
2418                                 # unary operator, or a cast
2419                                 } elsif ($op eq '!' || $op eq '~' ||
2420                                          $opv eq '*U' || $opv eq '-U' ||
2421                                          $opv eq '&U' || $opv eq '&&U') {
2422                                         if ($ctx !~ /[WEBC]x./ && $ca !~ /(?:\)|!|~|\*|-|\&|\||\+\+|\-\-|\{)$/) {
2423                                                 ERROR("SPACING",
2424                                                       "space required before that '$op' $at\n" . $hereptr);
2425                                         }
2426                                         if ($op eq '*' && $cc =~/\s*$Modifier\b/) {
2427                                                 # A unary '*' may be const
2428
2429                                         } elsif ($ctx =~ /.xW/) {
2430                                                 ERROR("SPACING",
2431                                                       "space prohibited after that '$op' $at\n" . $hereptr);
2432                                         }
2433
2434                                 # unary ++ and unary -- are allowed no space on one side.
2435                                 } elsif ($op eq '++' or $op eq '--') {
2436                                         if ($ctx !~ /[WEOBC]x[^W]/ && $ctx !~ /[^W]x[WOBEC]/) {
2437                                                 ERROR("SPACING",
2438                                                       "space required one side of that '$op' $at\n" . $hereptr);
2439                                         }
2440                                         if ($ctx =~ /Wx[BE]/ ||
2441                                             ($ctx =~ /Wx./ && $cc =~ /^;/)) {
2442                                                 ERROR("SPACING",
2443                                                       "space prohibited before that '$op' $at\n" . $hereptr);
2444                                         }
2445                                         if ($ctx =~ /ExW/) {
2446                                                 ERROR("SPACING",
2447                                                       "space prohibited after that '$op' $at\n" . $hereptr);
2448                                         }
2449
2450
2451                                 # << and >> may either have or not have spaces both sides
2452                                 } elsif ($op eq '<<' or $op eq '>>' or
2453                                          $op eq '&' or $op eq '^' or $op eq '|' or
2454                                          $op eq '+' or $op eq '-' or
2455                                          $op eq '*' or $op eq '/' or
2456                                          $op eq '%')
2457                                 {
2458                                         if ($ctx =~ /Wx[^WCE]|[^WCE]xW/) {
2459                                                 ERROR("SPACING",
2460                                                       "need consistent spacing around '$op' $at\n" .
2461                                                         $hereptr);
2462                                         }
2463
2464                                 # A colon needs no spaces before when it is
2465                                 # terminating a case value or a label.
2466                                 } elsif ($opv eq ':C' || $opv eq ':L') {
2467                                         if ($ctx =~ /Wx./) {
2468                                                 ERROR("SPACING",
2469                                                       "space prohibited before that '$op' $at\n" . $hereptr);
2470                                         }
2471
2472                                 # All the others need spaces both sides.
2473                                 } elsif ($ctx !~ /[EWC]x[CWE]/) {
2474                                         my $ok = 0;
2475
2476                                         # Ignore email addresses <foo@bar>
2477                                         if (($op eq '<' &&
2478                                              $cc =~ /^\S+\@\S+>/) ||
2479                                             ($op eq '>' &&
2480                                              $ca =~ /<\S+\@\S+$/))
2481                                         {
2482                                                 $ok = 1;
2483                                         }
2484
2485                                         # Ignore ?:
2486                                         if (($opv eq ':O' && $ca =~ /\?$/) ||
2487                                             ($op eq '?' && $cc =~ /^:/)) {
2488                                                 $ok = 1;
2489                                         }
2490
2491                                         if ($ok == 0) {
2492                                                 ERROR("SPACING",
2493                                                       "spaces required around that '$op' $at\n" . $hereptr);
2494                                         }
2495                                 }
2496                                 $off += length($elements[$n + 1]);
2497                         }
2498                 }
2499
2500 # check for multiple assignments
2501                 if ($line =~ /^.\s*$Lval\s*=\s*$Lval\s*=(?!=)/) {
2502                         CHK("MULTIPLE_ASSIGNMENTS",
2503                             "multiple assignments should be avoided\n" . $herecurr);
2504                 }
2505
2506 ## # check for multiple declarations, allowing for a function declaration
2507 ## # continuation.
2508 ##              if ($line =~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Ident.*/ &&
2509 ##                  $line !~ /^.\s*$Type\s+$Ident(?:\s*=[^,{]*)?\s*,\s*$Type\s*$Ident.*/) {
2510 ##
2511 ##                      # Remove any bracketed sections to ensure we do not
2512 ##                      # falsly report the parameters of functions.
2513 ##                      my $ln = $line;
2514 ##                      while ($ln =~ s/\([^\(\)]*\)//g) {
2515 ##                      }
2516 ##                      if ($ln =~ /,/) {
2517 ##                              WARN("MULTIPLE_DECLARATION",
2518 ##                                   "declaring multiple variables together should be avoided\n" . $herecurr);
2519 ##                      }
2520 ##              }
2521
2522 #need space before brace following if, while, etc
2523                 if (($line =~ /\(.*\){/ && $line !~ /\($Type\){/) ||
2524                     $line =~ /do{/) {
2525                         ERROR("SPACING",
2526                               "space required before the open brace '{'\n" . $herecurr);
2527                 }
2528
2529 # closing brace should have a space following it when it has anything
2530 # on the line
2531                 if ($line =~ /}(?!(?:,|;|\)))\S/) {
2532                         ERROR("SPACING",
2533                               "space required after that close brace '}'\n" . $herecurr);
2534                 }
2535
2536 # check spacing on square brackets
2537                 if ($line =~ /\[\s/ && $line !~ /\[\s*$/) {
2538                         ERROR("SPACING",
2539                               "space prohibited after that open square bracket '['\n" . $herecurr);
2540                 }
2541                 if ($line =~ /\s\]/) {
2542                         ERROR("SPACING",
2543                               "space prohibited before that close square bracket ']'\n" . $herecurr);
2544                 }
2545
2546 # check spacing on parentheses
2547                 if ($line =~ /\(\s/ && $line !~ /\(\s*(?:\\)?$/ &&
2548                     $line !~ /for\s*\(\s+;/) {
2549                         ERROR("SPACING",
2550                               "space prohibited after that open parenthesis '('\n" . $herecurr);
2551                 }
2552                 if ($line =~ /(\s+)\)/ && $line !~ /^.\s*\)/ &&
2553                     $line !~ /for\s*\(.*;\s+\)/ &&
2554                     $line !~ /:\s+\)/) {
2555                         ERROR("SPACING",
2556                               "space prohibited before that close parenthesis ')'\n" . $herecurr);
2557                 }
2558
2559 #goto labels aren't indented, allow a single space however
2560                 if ($line=~/^.\s+[A-Za-z\d_]+:(?![0-9]+)/ and
2561                    !($line=~/^. [A-Za-z\d_]+:/) and !($line=~/^.\s+default:/)) {
2562                         WARN("INDENTED_LABEL",
2563                              "labels should not be indented\n" . $herecurr);
2564                 }
2565
2566 # Return is not a function.
2567                 if (defined($stat) && $stat =~ /^.\s*return(\s*)(\(.*);/s) {
2568                         my $spacing = $1;
2569                         my $value = $2;
2570
2571                         # Flatten any parentheses
2572                         $value =~ s/\(/ \(/g;
2573                         $value =~ s/\)/\) /g;
2574                         while ($value =~ s/\[[^\{\}]*\]/1/ ||
2575                                $value !~ /(?:$Ident|-?$Constant)\s*
2576                                              $Compare\s*
2577                                              (?:$Ident|-?$Constant)/x &&
2578                                $value =~ s/\([^\(\)]*\)/1/) {
2579                         }
2580 #print "value<$value>\n";
2581                         if ($value =~ /^\s*(?:$Ident|-?$Constant)\s*$/) {
2582                                 ERROR("RETURN_PARENTHESES",
2583                                       "return is not a function, parentheses are not required\n" . $herecurr);
2584
2585                         } elsif ($spacing !~ /\s+/) {
2586                                 ERROR("SPACING",
2587                                       "space required before the open parenthesis '('\n" . $herecurr);
2588                         }
2589                 }
2590 # Return of what appears to be an errno should normally be -'ve
2591                 if ($line =~ /^.\s*return\s*(E[A-Z]*)\s*;/) {
2592                         my $name = $1;
2593                         if ($name ne 'EOF' && $name ne 'ERROR') {
2594                                 WARN("USE_NEGATIVE_ERRNO",
2595                                      "return of an errno should typically be -ve (return -$1)\n" . $herecurr);
2596                         }
2597                 }
2598
2599 # typecasts on min/max could be min_t/max_t
2600                 if ($line =~ /^\+(?:.*?)\b(min|max)\s*\($Typecast{0,1}($LvalOrFunc)\s*,\s*$Typecast{0,1}($LvalOrFunc)\s*\)/) {
2601                         if (defined $2 || defined $8) {
2602                                 my $call = $1;
2603                                 my $cast1 = deparenthesize($2);
2604                                 my $arg1 = $3;
2605                                 my $cast2 = deparenthesize($8);
2606                                 my $arg2 = $9;
2607                                 my $cast;
2608
2609                                 if ($cast1 ne "" && $cast2 ne "") {
2610                                         $cast = "$cast1 or $cast2";
2611                                 } elsif ($cast1 ne "") {
2612                                         $cast = $cast1;
2613                                 } else {
2614                                         $cast = $cast2;
2615                                 }
2616                                 WARN("MINMAX",
2617                                      "$call() should probably be ${call}_t($cast, $arg1, $arg2)\n" . $herecurr);
2618                         }
2619                 }
2620
2621 # Need a space before open parenthesis after if, while etc
2622                 if ($line=~/\b(if|while|for|switch)\(/) {
2623                         ERROR("SPACING", "space required before the open parenthesis '('\n" . $herecurr);
2624                 }
2625
2626 # Check for illegal assignment in if conditional -- and check for trailing
2627 # statements after the conditional.
2628                 if ($line =~ /do\s*(?!{)/) {
2629                         my ($stat_next) = ctx_statement_block($line_nr_next,
2630                                                 $remain_next, $off_next);
2631                         $stat_next =~ s/\n./\n /g;
2632                         ##print "stat<$stat> stat_next<$stat_next>\n";
2633
2634                         if ($stat_next =~ /^\s*while\b/) {
2635                                 # If the statement carries leading newlines,
2636                                 # then count those as offsets.
2637                                 my ($whitespace) =
2638                                         ($stat_next =~ /^((?:\s*\n[+-])*\s*)/s);
2639                                 my $offset =
2640                                         statement_rawlines($whitespace) - 1;
2641
2642                                 $suppress_whiletrailers{$line_nr_next +
2643                                                                 $offset} = 1;
2644                         }
2645                 }
2646                 if (!defined $suppress_whiletrailers{$linenr} &&
2647                     $line =~ /\b(?:if|while|for)\s*\(/ && $line !~ /^.\s*#/) {
2648                         my ($s, $c) = ($stat, $cond);
2649
2650                         if ($c =~ /\bif\s*\(.*[^<>!=]=[^=].*/s) {
2651                                 ERROR("ASSIGN_IN_IF",
2652                                       "do not use assignment in if condition\n" . $herecurr);
2653                         }
2654
2655                         # Find out what is on the end of the line after the
2656                         # conditional.
2657                         substr($s, 0, length($c), '');
2658                         $s =~ s/\n.*//g;
2659                         $s =~ s/$;//g;  # Remove any comments
2660                         if (length($c) && $s !~ /^\s*{?\s*\\*\s*$/ &&
2661                             $c !~ /}\s*while\s*/)
2662                         {
2663                                 # Find out how long the conditional actually is.
2664                                 my @newlines = ($c =~ /\n/gs);
2665                                 my $cond_lines = 1 + $#newlines;
2666                                 my $stat_real = '';
2667
2668                                 $stat_real = raw_line($linenr, $cond_lines)
2669                                                         . "\n" if ($cond_lines);
2670                                 if (defined($stat_real) && $cond_lines > 1) {
2671                                         $stat_real = "[...]\n$stat_real";
2672                                 }
2673
2674                                 ERROR("TRAILING_STATEMENTS",
2675                                       "trailing statements should be on next line\n" . $herecurr . $stat_real);
2676                         }
2677                 }
2678
2679 # Check for bitwise tests written as boolean
2680                 if ($line =~ /
2681                         (?:
2682                                 (?:\[|\(|\&\&|\|\|)
2683                                 \s*0[xX][0-9]+\s*
2684                                 (?:\&\&|\|\|)
2685                         |
2686                                 (?:\&\&|\|\|)
2687                                 \s*0[xX][0-9]+\s*
2688                                 (?:\&\&|\|\||\)|\])
2689                         )/x)
2690                 {
2691                         WARN("HEXADECIMAL_BOOLEAN_TEST",
2692                              "boolean test with hexadecimal, perhaps just 1 \& or \|?\n" . $herecurr);
2693                 }
2694
2695 # if and else should not have general statements after it
2696                 if ($line =~ /^.\s*(?:}\s*)?else\b(.*)/) {
2697                         my $s = $1;
2698                         $s =~ s/$;//g;  # Remove any comments
2699                         if ($s !~ /^\s*(?:\sif|(?:{|)\s*\\?\s*$)/) {
2700                                 ERROR("TRAILING_STATEMENTS",
2701                                       "trailing statements should be on next line\n" . $herecurr);
2702                         }
2703                 }
2704 # if should not continue a brace
2705                 if ($line =~ /}\s*if\b/) {
2706                         ERROR("TRAILING_STATEMENTS",
2707                               "trailing statements should be on next line\n" .
2708                                 $herecurr);
2709                 }
2710 # case and default should not have general statements after them
2711                 if ($line =~ /^.\s*(?:case\s*.*|default\s*):/g &&
2712                     $line !~ /\G(?:
2713                         (?:\s*$;*)(?:\s*{)?(?:\s*$;*)(?:\s*\\)?\s*$|
2714                         \s*return\s+
2715                     )/xg)
2716                 {
2717                         ERROR("TRAILING_STATEMENTS",
2718                               "trailing statements should be on next line\n" . $herecurr);
2719                 }
2720
2721                 # Check for }<nl>else {, these must be at the same
2722                 # indent level to be relevant to each other.
2723                 if ($prevline=~/}\s*$/ and $line=~/^.\s*else\s*/ and
2724                                                 $previndent == $indent) {
2725                         ERROR("ELSE_AFTER_BRACE",
2726                               "else should follow close brace '}'\n" . $hereprev);
2727                 }
2728
2729                 if ($prevline=~/}\s*$/ and $line=~/^.\s*while\s*/ and
2730                                                 $previndent == $indent) {
2731                         my ($s, $c) = ctx_statement_block($linenr, $realcnt, 0);
2732
2733                         # Find out what is on the end of the line after the
2734                         # conditional.
2735                         substr($s, 0, length($c), '');
2736                         $s =~ s/\n.*//g;
2737
2738                         if ($s =~ /^\s*;/) {
2739                                 ERROR("WHILE_AFTER_BRACE",
2740                                       "while should follow close brace '}'\n" . $hereprev);
2741                         }
2742                 }
2743
2744 #studly caps, commented out until figure out how to distinguish between use of existing and adding new
2745 #               if (($line=~/[\w_][a-z\d]+[A-Z]/) and !($line=~/print/)) {
2746 #                   print "No studly caps, use _\n";
2747 #                   print "$herecurr";
2748 #                   $clean = 0;
2749 #               }
2750
2751 #no spaces allowed after \ in define
2752                 if ($line=~/\#\s*define.*\\\s$/) {
2753                         WARN("WHITESPACE_AFTER_LINE_CONTINUATION",
2754                              "Whitepspace after \\ makes next lines useless\n" . $herecurr);
2755                 }
2756
2757 #warn if <asm/foo.h> is #included and <linux/foo.h> is available (uses RAW line)
2758                 if ($tree && $rawline =~ m{^.\s*\#\s*include\s*\<asm\/(.*)\.h\>}) {
2759                         my $file = "$1.h";
2760                         my $checkfile = "include/linux/$file";
2761                         if (-f "$root/$checkfile" &&
2762                             $realfile ne $checkfile &&
2763                             $1 !~ /$allowed_asm_includes/)
2764                         {
2765                                 if ($realfile =~ m{^arch/}) {
2766                                         CHK("ARCH_INCLUDE_LINUX",
2767                                             "Consider using #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2768                                 } else {
2769                                         WARN("INCLUDE_LINUX",
2770                                              "Use #include <linux/$file> instead of <asm/$file>\n" . $herecurr);
2771                                 }
2772                         }
2773                 }
2774
2775 # multi-statement macros should be enclosed in a do while loop, grab the
2776 # first statement and ensure its the whole macro if its not enclosed
2777 # in a known good container
2778                 if ($realfile !~ m@/vmlinux.lds.h$@ &&
2779                     $line =~ /^.\s*\#\s*define\s*$Ident(\()?/) {
2780                         my $ln = $linenr;
2781                         my $cnt = $realcnt;
2782                         my ($off, $dstat, $dcond, $rest);
2783                         my $ctx = '';
2784
2785                         my $args = defined($1);
2786
2787                         # Find the end of the macro and limit our statement
2788                         # search to that.
2789                         while ($cnt > 0 && defined $lines[$ln - 1] &&
2790                                 $lines[$ln - 1] =~ /^(?:-|..*\\$)/)
2791                         {
2792                                 $ctx .= $rawlines[$ln - 1] . "\n";
2793                                 $cnt-- if ($lines[$ln - 1] !~ /^-/);
2794                                 $ln++;
2795                         }
2796                         $ctx .= $rawlines[$ln - 1];
2797
2798                         ($dstat, $dcond, $ln, $cnt, $off) =
2799                                 ctx_statement_block($linenr, $ln - $linenr + 1, 0);
2800                         #print "dstat<$dstat> dcond<$dcond> cnt<$cnt> off<$off>\n";
2801                         #print "LINE<$lines[$ln-1]> len<" . length($lines[$ln-1]) . "\n";
2802
2803                         # Extract the remainder of the define (if any) and
2804                         # rip off surrounding spaces, and trailing \'s.
2805                         $rest = '';
2806                         while ($off != 0 || ($cnt > 0 && $rest =~ /\\\s*$/)) {
2807                                 #print "ADDING cnt<$cnt> $off <" . substr($lines[$ln - 1], $off) . "> rest<$rest>\n";
2808                                 if ($off != 0 || $lines[$ln - 1] !~ /^-/) {
2809                                         $rest .= substr($lines[$ln - 1], $off) . "\n";
2810                                         $cnt--;
2811                                 }
2812                                 $ln++;
2813                                 $off = 0;
2814                         }
2815                         $rest =~ s/\\\n.//g;
2816                         $rest =~ s/^\s*//s;
2817                         $rest =~ s/\s*$//s;
2818
2819                         # Clean up the original statement.
2820                         if ($args) {
2821                                 substr($dstat, 0, length($dcond), '');
2822                         } else {
2823                                 $dstat =~ s/^.\s*\#\s*define\s+$Ident\s*//;
2824                         }
2825                         $dstat =~ s/$;//g;
2826                         $dstat =~ s/\\\n.//g;
2827                         $dstat =~ s/^\s*//s;
2828                         $dstat =~ s/\s*$//s;
2829
2830                         # Flatten any parentheses and braces
2831                         while ($dstat =~ s/\([^\(\)]*\)/1/ ||
2832                                $dstat =~ s/\{[^\{\}]*\}/1/ ||
2833                                $dstat =~ s/\[[^\{\}]*\]/1/)
2834                         {
2835                         }
2836
2837                         my $exceptions = qr{
2838                                 $Declare|
2839                                 module_param_named|
2840                                 MODULE_PARAM_DESC|
2841                                 DECLARE_PER_CPU|
2842                                 DEFINE_PER_CPU|
2843                                 __typeof__\(|
2844                                 union|
2845                                 struct|
2846                                 \.$Ident\s*=\s*|
2847                                 ^\"|\"$
2848                         }x;
2849                         #print "REST<$rest> dstat<$dstat> ctx<$ctx>\n";
2850                         if ($rest ne '' && $rest ne ',') {
2851                                 if ($rest !~ /while\s*\(/ &&
2852                                     $dstat !~ /$exceptions/)
2853                                 {
2854                                         ERROR("MULTISTATEMENT_MACRO_USE_DO_WHILE",
2855                                               "Macros with multiple statements should be enclosed in a do - while loop\n" . "$here\n$ctx\n");
2856                                 }
2857
2858                         } elsif ($ctx !~ /;/) {
2859                                 if ($dstat ne '' &&
2860                                     $dstat !~ /^(?:$Ident|-?$Constant)$/ &&
2861                                     $dstat !~ /$exceptions/ &&
2862                                     $dstat !~ /^\.$Ident\s*=/ &&
2863                                     $dstat =~ /$Operators/)
2864                                 {
2865                                         ERROR("COMPLEX_MACRO",
2866                                               "Macros with complex values should be enclosed in parenthesis\n" . "$here\n$ctx\n");
2867                                 }
2868                         }
2869                 }
2870
2871 # make sure symbols are always wrapped with VMLINUX_SYMBOL() ...
2872 # all assignments may have only one of the following with an assignment:
2873 #       .
2874 #       ALIGN(...)
2875 #       VMLINUX_SYMBOL(...)
2876                 if ($realfile eq 'vmlinux.lds.h' && $line =~ /(?:(?:^|\s)$Ident\s*=|=\s*$Ident(?:\s|$))/) {
2877                         WARN("MISSING_VMLINUX_SYMBOL",
2878                              "vmlinux.lds.h needs VMLINUX_SYMBOL() around C-visible symbols\n" . $herecurr);
2879                 }
2880
2881 # check for redundant bracing round if etc
2882                 if ($line =~ /(^.*)\bif\b/ && $1 !~ /else\s*$/) {
2883                         my ($level, $endln, @chunks) =
2884                                 ctx_statement_full($linenr, $realcnt, 1);
2885                         #print "chunks<$#chunks> linenr<$linenr> endln<$endln> level<$level>\n";
2886                         #print "APW: <<$chunks[1][0]>><<$chunks[1][1]>>\n";
2887                         if ($#chunks > 0 && $level == 0) {
2888                                 my $allowed = 0;
2889                                 my $seen = 0;
2890                                 my $herectx = $here . "\n";
2891                                 my $ln = $linenr - 1;
2892                                 for my $chunk (@chunks) {
2893                                         my ($cond, $block) = @{$chunk};
2894
2895                                         # If the condition carries leading newlines, then count those as offsets.
2896                                         my ($whitespace) = ($cond =~ /^((?:\s*\n[+-])*\s*)/s);
2897                                         my $offset = statement_rawlines($whitespace) - 1;
2898
2899                                         #print "COND<$cond> whitespace<$whitespace> offset<$offset>\n";
2900
2901                                         # We have looked at and allowed this specific line.
2902                                         $suppress_ifbraces{$ln + $offset} = 1;
2903
2904                                         $herectx .= "$rawlines[$ln + $offset]\n[...]\n";
2905                                         $ln += statement_rawlines($block) - 1;
2906
2907                                         substr($block, 0, length($cond), '');
2908
2909                                         $seen++ if ($block =~ /^\s*{/);
2910
2911                                         #print "cond<$cond> block<$block> allowed<$allowed>\n";
2912                                         if (statement_lines($cond) > 1) {
2913                                                 #print "APW: ALLOWED: cond<$cond>\n";
2914                                                 $allowed = 1;
2915                                         }
2916                                         if ($block =~/\b(?:if|for|while)\b/) {
2917                                                 #print "APW: ALLOWED: block<$block>\n";
2918                                                 $allowed = 1;
2919                                         }
2920                                         if (statement_block_size($block) > 1) {
2921                                                 #print "APW: ALLOWED: lines block<$block>\n";
2922                                                 $allowed = 1;
2923                                         }
2924                                 }
2925                                 if ($seen && !$allowed) {
2926                                         WARN("BRACES",
2927                                              "braces {} are not necessary for any arm of this statement\n" . $herectx);
2928                                 }
2929                         }
2930                 }
2931                 if (!defined $suppress_ifbraces{$linenr - 1} &&
2932                                         $line =~ /\b(if|while|for|else)\b/) {
2933                         my $allowed = 0;
2934
2935                         # Check the pre-context.
2936                         if (substr($line, 0, $-[0]) =~ /(\}\s*)$/) {
2937                                 #print "APW: ALLOWED: pre<$1>\n";
2938                                 $allowed = 1;
2939                         }
2940
2941                         my ($level, $endln, @chunks) =
2942                                 ctx_statement_full($linenr, $realcnt, $-[0]);
2943
2944                         # Check the condition.
2945                         my ($cond, $block) = @{$chunks[0]};
2946                         #print "CHECKING<$linenr> cond<$cond> block<$block>\n";
2947                         if (defined $cond) {
2948                                 substr($block, 0, length($cond), '');
2949                         }
2950                         if (statement_lines($cond) > 1) {
2951                                 #print "APW: ALLOWED: cond<$cond>\n";
2952                                 $allowed = 1;
2953                         }
2954                         if ($block =~/\b(?:if|for|while)\b/) {
2955                                 #print "APW: ALLOWED: block<$block>\n";
2956                                 $allowed = 1;
2957                         }
2958                         if (statement_block_size($block) > 1) {
2959                                 #print "APW: ALLOWED: lines block<$block>\n";
2960                                 $allowed = 1;
2961                         }
2962                         # Check the post-context.
2963                         if (defined $chunks[1]) {
2964                                 my ($cond, $block) = @{$chunks[1]};
2965                                 if (defined $cond) {
2966                                         substr($block, 0, length($cond), '');
2967                                 }
2968                                 if ($block =~ /^\s*\{/) {
2969                                         #print "APW: ALLOWED: chunk-1 block<$block>\n";
2970                                         $allowed = 1;
2971                                 }
2972                         }
2973                         if ($level == 0 && $block =~ /^\s*\{/ && !$allowed) {
2974                                 my $herectx = $here . "\n";
2975                                 my $cnt = statement_rawlines($block);
2976
2977                                 for (my $n = 0; $n < $cnt; $n++) {
2978                                         $herectx .= raw_line($linenr, $n) . "\n";
2979                                 }
2980
2981                                 WARN("BRACES",
2982                                      "braces {} are not necessary for single statement blocks\n" . $herectx);
2983                         }
2984                 }
2985
2986 # don't include deprecated include files (uses RAW line)
2987                 for my $inc (@dep_includes) {
2988                         if ($rawline =~ m@^.\s*\#\s*include\s*\<$inc>@) {
2989                                 ERROR("DEPRECATED_INCLUDE",
2990                                       "Don't use <$inc>: see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2991                         }
2992                 }
2993
2994 # don't use deprecated functions
2995                 for my $func (@dep_functions) {
2996                         if ($line =~ /\b$func\b/) {
2997                                 ERROR("DEPRECATED_FUNCTION",
2998                                       "Don't use $func(): see Documentation/feature-removal-schedule.txt\n" . $herecurr);
2999                         }
3000                 }
3001
3002 # no volatiles please
3003                 my $asm_volatile = qr{\b(__asm__|asm)\s+(__volatile__|volatile)\b};
3004                 if ($line =~ /\bvolatile\b/ && $line !~ /$asm_volatile/) {
3005                         WARN("VOLATILE",
3006                              "Use of volatile is usually wrong: see Documentation/volatile-considered-harmful.txt\n" . $herecurr);
3007                 }
3008
3009 # warn about #if 0
3010                 if ($line =~ /^.\s*\#\s*if\s+0\b/) {
3011                         CHK("REDUNDANT_CODE",
3012                             "if this code is redundant consider removing it\n" .
3013                                 $herecurr);
3014                 }
3015
3016 # check for needless kfree() checks
3017                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
3018                         my $expr = $1;
3019                         if ($line =~ /\bkfree\(\Q$expr\E\);/) {
3020                                 WARN("NEEDLESS_KFREE",
3021                                      "kfree(NULL) is safe this check is probably not required\n" . $hereprev);
3022                         }
3023                 }
3024 # check for needless usb_free_urb() checks
3025                 if ($prevline =~ /\bif\s*\(([^\)]*)\)/) {
3026                         my $expr = $1;
3027                         if ($line =~ /\busb_free_urb\(\Q$expr\E\);/) {
3028                                 WARN("NEEDLESS_USB_FREE_URB",
3029                                      "usb_free_urb(NULL) is safe this check is probably not required\n" . $hereprev);
3030                         }
3031                 }
3032
3033 # prefer usleep_range over udelay
3034                 if ($line =~ /\budelay\s*\(\s*(\w+)\s*\)/) {
3035                         # ignore udelay's < 10, however
3036                         if (! (($1 =~ /(\d+)/) && ($1 < 10)) ) {
3037                                 CHK("USLEEP_RANGE",
3038                                     "usleep_range is preferred over udelay; see Documentation/timers/timers-howto.txt\n" . $line);
3039                         }
3040                 }
3041
3042 # warn about unexpectedly long msleep's
3043                 if ($line =~ /\bmsleep\s*\((\d+)\);/) {
3044                         if ($1 < 20) {
3045                                 WARN("MSLEEP",
3046                                      "msleep < 20ms can sleep for up to 20ms; see Documentation/timers/timers-howto.txt\n" . $line);
3047                         }
3048                 }
3049
3050 # warn about #ifdefs in C files
3051 #               if ($line =~ /^.\s*\#\s*if(|n)def/ && ($realfile =~ /\.c$/)) {
3052 #                       print "#ifdef in C files should be avoided\n";
3053 #                       print "$herecurr";
3054 #                       $clean = 0;
3055 #               }
3056
3057 # warn about spacing in #ifdefs
3058                 if ($line =~ /^.\s*\#\s*(ifdef|ifndef|elif)\s\s+/) {
3059                         ERROR("SPACING",
3060                               "exactly one space required after that #$1\n" . $herecurr);
3061                 }
3062
3063 # check for spinlock_t definitions without a comment.
3064                 if ($line =~ /^.\s*(struct\s+mutex|spinlock_t)\s+\S+;/ ||
3065                     $line =~ /^.\s*(DEFINE_MUTEX)\s*\(/) {
3066                         my $which = $1;
3067                         if (!ctx_has_comment($first_line, $linenr)) {
3068                                 CHK("UNCOMMENTED_DEFINITION",
3069                                     "$1 definition without comment\n" . $herecurr);
3070                         }
3071                 }
3072 # check for memory barriers without a comment.
3073                 if ($line =~ /\b(mb|rmb|wmb|read_barrier_depends|smp_mb|smp_rmb|smp_wmb|smp_read_barrier_depends)\(/) {
3074                         if (!ctx_has_comment($first_line, $linenr)) {
3075                                 CHK("MEMORY_BARRIER",
3076                                     "memory barrier without comment\n" . $herecurr);
3077                         }
3078                 }
3079 # check of hardware specific defines
3080                 if ($line =~ m@^.\s*\#\s*if.*\b(__i386__|__powerpc64__|__sun__|__s390x__)\b@ && $realfile !~ m@include/asm-@) {
3081                         CHK("ARCH_DEFINES",
3082                             "architecture specific defines should be avoided\n" .  $herecurr);
3083                 }
3084
3085 # Check that the storage class is at the beginning of a declaration
3086                 if ($line =~ /\b$Storage\b/ && $line !~ /^.\s*$Storage\b/) {
3087                         WARN("STORAGE_CLASS",
3088                              "storage class should be at the beginning of the declaration\n" . $herecurr)
3089                 }
3090
3091 # check the location of the inline attribute, that it is between
3092 # storage class and type.
3093                 if ($line =~ /\b$Type\s+$Inline\b/ ||
3094                     $line =~ /\b$Inline\s+$Storage\b/) {
3095                         ERROR("INLINE_LOCATION",
3096                               "inline keyword should sit between storage class and type\n" . $herecurr);
3097                 }
3098
3099 # Check for __inline__ and __inline, prefer inline
3100                 if ($line =~ /\b(__inline__|__inline)\b/) {
3101                         WARN("INLINE",
3102                              "plain inline is preferred over $1\n" . $herecurr);
3103                 }
3104
3105 # Check for __attribute__ packed, prefer __packed
3106                 if ($line =~ /\b__attribute__\s*\(\s*\(.*\bpacked\b/) {
3107                         WARN("PREFER_PACKED",
3108                              "__packed is preferred over __attribute__((packed))\n" . $herecurr);
3109                 }
3110
3111 # Check for __attribute__ aligned, prefer __aligned
3112                 if ($line =~ /\b__attribute__\s*\(\s*\(.*aligned/) {
3113                         WARN("PREFER_ALIGNED",
3114                              "__aligned(size) is preferred over __attribute__((aligned(size)))\n" . $herecurr);
3115                 }
3116
3117 # check for sizeof(&)
3118                 if ($line =~ /\bsizeof\s*\(\s*\&/) {
3119                         WARN("SIZEOF_ADDRESS",
3120                              "sizeof(& should be avoided\n" . $herecurr);
3121                 }
3122
3123 # check for line continuations in quoted strings with odd counts of "
3124                 if ($rawline =~ /\\$/ && $rawline =~ tr/"/"/ % 2) {
3125                         WARN("LINE_CONTINUATIONS",
3126                              "Avoid line continuations in quoted strings\n" . $herecurr);
3127                 }
3128
3129 # check for new externs in .c files.
3130                 if ($realfile =~ /\.c$/ && defined $stat &&
3131                     $stat =~ /^.\s*(?:extern\s+)?$Type\s+($Ident)(\s*)\(/s)
3132                 {
3133                         my $function_name = $1;
3134                         my $paren_space = $2;
3135
3136                         my $s = $stat;
3137                         if (defined $cond) {
3138                                 substr($s, 0, length($cond), '');
3139                         }
3140                         if ($s =~ /^\s*;/ &&
3141                             $function_name ne 'uninitialized_var')
3142                         {
3143                                 WARN("AVOID_EXTERNS",
3144                                      "externs should be avoided in .c files\n" .  $herecurr);
3145                         }
3146
3147                         if ($paren_space =~ /\n/) {
3148                                 WARN("FUNCTION_ARGUMENTS",
3149                                      "arguments for function declarations should follow identifier\n" . $herecurr);
3150                         }
3151
3152                 } elsif ($realfile =~ /\.c$/ && defined $stat &&
3153                     $stat =~ /^.\s*extern\s+/)
3154                 {
3155                         WARN("AVOID_EXTERNS",
3156                              "externs should be avoided in .c files\n" .  $herecurr);
3157                 }
3158
3159 # checks for new __setup's
3160                 if ($rawline =~ /\b__setup\("([^"]*)"/) {
3161                         my $name = $1;
3162
3163                         if (!grep(/$name/, @setup_docs)) {
3164                                 CHK("UNDOCUMENTED_SETUP",
3165                                     "__setup appears un-documented -- check Documentation/kernel-parameters.txt\n" . $herecurr);
3166                         }
3167                 }
3168
3169 # check for pointless casting of kmalloc return
3170                 if ($line =~ /\*\s*\)\s*[kv][czm]alloc(_node){0,1}\b/) {
3171                         WARN("UNNECESSARY_CASTS",
3172                              "unnecessary cast may hide bugs, see http://c-faq.com/malloc/mallocnocast.html\n" . $herecurr);
3173                 }
3174
3175 # check for multiple semicolons
3176                 if ($line =~ /;\s*;\s*$/) {
3177                     WARN("ONE_SEMICOLON",
3178                          "Statements terminations use 1 semicolon\n" . $herecurr);
3179                 }
3180
3181 # check for gcc specific __FUNCTION__
3182                 if ($line =~ /__FUNCTION__/) {
3183                         WARN("USE_FUNC",
3184                              "__func__ should be used instead of gcc specific __FUNCTION__\n"  . $herecurr);
3185                 }
3186
3187 # check for semaphores initialized locked
3188                 if ($line =~ /^.\s*sema_init.+,\W?0\W?\)/) {
3189                         WARN("CONSIDER_COMPLETION",
3190                              "consider using a completion\n" . $herecurr);
3191
3192                 }
3193 # recommend kstrto* over simple_strto* and strict_strto*
3194                 if ($line =~ /\b((simple|strict)_(strto(l|ll|ul|ull)))\s*\(/) {
3195                         WARN("CONSIDER_KSTRTO",
3196                              "$1 is obsolete, use k$3 instead\n" . $herecurr);
3197                 }
3198 # check for __initcall(), use device_initcall() explicitly please
3199                 if ($line =~ /^.\s*__initcall\s*\(/) {
3200                         WARN("USE_DEVICE_INITCALL",
3201                              "please use device_initcall() instead of __initcall()\n" . $herecurr);
3202                 }
3203 # check for various ops structs, ensure they are const.
3204                 my $struct_ops = qr{acpi_dock_ops|
3205                                 address_space_operations|
3206                                 backlight_ops|
3207                                 block_device_operations|
3208                                 dentry_operations|
3209                                 dev_pm_ops|
3210                                 dma_map_ops|
3211                                 extent_io_ops|
3212                                 file_lock_operations|
3213                                 file_operations|
3214                                 hv_ops|
3215                                 ide_dma_ops|
3216                                 intel_dvo_dev_ops|
3217                                 item_operations|
3218                                 iwl_ops|
3219                                 kgdb_arch|
3220                                 kgdb_io|
3221                                 kset_uevent_ops|
3222                                 lock_manager_operations|
3223                                 microcode_ops|
3224                                 mtrr_ops|
3225                                 neigh_ops|
3226                                 nlmsvc_binding|
3227                                 pci_raw_ops|
3228                                 pipe_buf_operations|
3229                                 platform_hibernation_ops|
3230                                 platform_suspend_ops|
3231                                 proto_ops|
3232                                 rpc_pipe_ops|
3233                                 seq_operations|
3234                                 snd_ac97_build_ops|
3235                                 soc_pcmcia_socket_ops|
3236                                 stacktrace_ops|
3237                                 sysfs_ops|
3238                                 tty_operations|
3239                                 usb_mon_operations|
3240                                 wd_ops}x;
3241                 if ($line !~ /\bconst\b/ &&
3242                     $line =~ /\bstruct\s+($struct_ops)\b/) {
3243                         WARN("CONST_STRUCT",
3244                              "struct $1 should normally be const\n" .
3245                                 $herecurr);
3246                 }
3247
3248 # use of NR_CPUS is usually wrong
3249 # ignore definitions of NR_CPUS and usage to define arrays as likely right
3250                 if ($line =~ /\bNR_CPUS\b/ &&
3251                     $line !~ /^.\s*\s*#\s*if\b.*\bNR_CPUS\b/ &&
3252                     $line !~ /^.\s*\s*#\s*define\b.*\bNR_CPUS\b/ &&
3253                     $line !~ /^.\s*$Declare\s.*\[[^\]]*NR_CPUS[^\]]*\]/ &&
3254                     $line !~ /\[[^\]]*\.\.\.[^\]]*NR_CPUS[^\]]*\]/ &&
3255                     $line !~ /\[[^\]]*NR_CPUS[^\]]*\.\.\.[^\]]*\]/)
3256                 {
3257                         WARN("NR_CPUS",
3258                              "usage of NR_CPUS is often wrong - consider using cpu_possible(), num_possible_cpus(), for_each_possible_cpu(), etc\n" . $herecurr);
3259                 }
3260
3261 # check for %L{u,d,i} in strings
3262                 my $string;
3263                 while ($line =~ /(?:^|")([X\t]*)(?:"|$)/g) {
3264                         $string = substr($rawline, $-[1], $+[1] - $-[1]);
3265                         $string =~ s/%%/__/g;
3266                         if ($string =~ /(?<!%)%L[udi]/) {
3267                                 WARN("PRINTF_L",
3268                                      "\%Ld/%Lu are not-standard C, use %lld/%llu\n" . $herecurr);
3269                                 last;
3270                         }
3271                 }
3272
3273 # whine mightly about in_atomic
3274                 if ($line =~ /\bin_atomic\s*\(/) {
3275                         if ($realfile =~ m@^drivers/@) {
3276                                 ERROR("IN_ATOMIC",
3277                                       "do not use in_atomic in drivers\n" . $herecurr);
3278                         } elsif ($realfile !~ m@^kernel/@) {
3279                                 WARN("IN_ATOMIC",
3280                                      "use of in_atomic() is incorrect outside core kernel code\n" . $herecurr);
3281                         }
3282                 }
3283
3284 # check for lockdep_set_novalidate_class
3285                 if ($line =~ /^.\s*lockdep_set_novalidate_class\s*\(/ ||
3286                     $line =~ /__lockdep_no_validate__\s*\)/ ) {
3287                         if ($realfile !~ m@^kernel/lockdep@ &&
3288                             $realfile !~ m@^include/linux/lockdep@ &&
3289                             $realfile !~ m@^drivers/base/core@) {
3290                                 ERROR("LOCKDEP",
3291                                       "lockdep_no_validate class is reserved for device->mutex.\n" . $herecurr);
3292                         }
3293                 }
3294
3295                 if ($line =~ /debugfs_create_file.*S_IWUGO/ ||
3296                     $line =~ /DEVICE_ATTR.*S_IWUGO/ ) {
3297                         WARN("EXPORTED_WORLD_WRITABLE",
3298                              "Exporting world writable files is usually an error. Consider more restrictive permissions.\n" . $herecurr);
3299                 }
3300
3301                 # Check for memset with swapped arguments
3302                 if ($line =~ /memset.*\,(\ |)(0x|)0(\ |0|)\);/) {
3303                         ERROR("MEMSET",
3304                               "memset size is 3rd argument, not the second.\n" . $herecurr);
3305                 }
3306         }
3307
3308         # If we have no input at all, then there is nothing to report on
3309         # so just keep quiet.
3310         if ($#rawlines == -1) {
3311                 exit(0);
3312         }
3313
3314         # In mailback mode only produce a report in the negative, for
3315         # things that appear to be patches.
3316         if ($mailback && ($clean == 1 || !$is_patch)) {
3317                 exit(0);
3318         }
3319
3320         # This is not a patch, and we are are in 'no-patch' mode so
3321         # just keep quiet.
3322         if (!$chk_patch && !$is_patch) {
3323                 exit(0);
3324         }
3325
3326         if (!$is_patch) {
3327                 ERROR("NOT_UNIFIED_DIFF",
3328                       "Does not appear to be a unified-diff format patch\n");
3329         }
3330         if ($is_patch && $chk_signoff && $signoff == 0) {
3331                 ERROR("MISSING_SIGN_OFF",
3332                       "Missing Signed-off-by: line(s)\n");
3333         }
3334
3335         print report_dump();
3336         if ($summary && !($clean == 1 && $quiet == 1)) {
3337                 print "$filename " if ($summary_file);
3338                 print "total: $cnt_error errors, $cnt_warn warnings, " .
3339                         (($check)? "$cnt_chk checks, " : "") .
3340                         "$cnt_lines lines checked\n";
3341                 print "\n" if ($quiet == 0);
3342         }
3343
3344         if ($quiet == 0) {
3345                 # If there were whitespace errors which cleanpatch can fix
3346                 # then suggest that.
3347                 if ($rpt_cleaners) {
3348                         print "NOTE: whitespace errors detected, you may wish to use scripts/cleanpatch or\n";
3349                         print "      scripts/cleanfile\n\n";
3350                         $rpt_cleaners = 0;
3351                 }
3352         }
3353
3354         if (keys %ignore_type) {
3355             print "NOTE: Ignored message types:";
3356             foreach my $ignore (sort keys %ignore_type) {
3357                 print " $ignore";
3358             }
3359             print "\n";
3360             print "\n" if ($quiet == 0);
3361         }
3362
3363         if ($clean == 1 && $quiet == 0) {
3364                 print "$vname has no obvious style problems and is ready for submission.\n"
3365         }
3366         if ($clean == 0 && $quiet == 0) {
3367                 print << "EOM";
3368 $vname has style problems, please review.
3369
3370 If any of these errors are false positives, please report
3371 them to the maintainer, see CHECKPATCH in MAINTAINERS.
3372 EOM
3373         }
3374
3375         return $clean;
3376 }